excel macro deleting extra rows - vba

Question

I have a macro that deletes the rows I don't want in excel. it deletes rows that have a time before 9:30 am and after 4:00 pm. For some reason, it also deletes the rows that have time of 10:00 am to 10:09 am, 11:00 am to 11:09 am, 12:00 pm to 12:09 pm, 1:00 pm to 1:09 pm, 2:00 pm to 2:09 pm, 3:00 pm to 3:09 pm
please help me so it does not delete those rows.
my code:
Sub DeleteRows()
Dim lastRow As Long
Dim Cell As Long
Dim dt As Date
'Work with the active sheet.
With ActiveSheet
'Find the last row of your dataset.
lastRow = .Range("A:A").Find("*", searchdirection:=xlPrevious).Row
'Format your time column to a readable time.
.Columns("B").NumberFormat = "[$-F400]h:mm:ss AM/PM"
'Loop through the rows, beginning at the bottom.
For Cell = lastRow To 2 Step -1
'Piece together the date.
dt = Mid(.Cells(Cell, 1), 5, 2) & "/" & _
Mid(.Cells(Cell, 1), 7, 2) & "/" & Left(.Cells(Cell, 1), 4)
'If the date is a Sat or Sun, delete the row.
If Weekday(dt) = 1 Or Weekday(dt) = 7 Then
.Rows(Cell).EntireRow.Delete
'If the time is before 9:30am or after 4pm, delete the row.
ElseIf CInt(Hour(.Cells(Cell, 2)) & Minute(.Cells(Cell, 2))) < 930 Or _
CInt(Hour(.Cells(Cell, 2)) & Minute(.Cells(Cell, 2))) > 1600 Then
.Rows(Cell).EntireRow.Delete
End If
Next Cell
End With
MsgBox "Done!"

Answer 1

You could try checking the value against an actual time:
'If the time is before 9:30am or after 4pm, delete the row.
ElseIf .Cells(Cell, 2) - Int(.Cells(Cell, 2)) < CDate("09:30:00") Or _
.Cells(Cell, 2) - Int (.Cells(Cell, 2)) > CDate("16:00:01") Then
.Rows(Cell).EntireRow.Delete
Note the upper bound 16:00:01 avoids a boundary evaluation error (probably due to rounding) at 16:00:00.

Answer 2

Instead of using
CInt(Hour(.Cells(Cell, 2)) & Minute(.Cells(Cell, 2)))
use
100*Hour(.Cells(Cell, 2)) + Minute(.Cells(Cell, 2))
You are hitting your problem because, for example, 11:08 is being converted into 11 hours and 8 minutes, which when concatenated together in your code yields 118 (which meets the deletion condition of being less than 930). The revised version (untested) should convert it to 1108 and avoid meeting the deletion condition.