Strange syntax error in yacc program - syntax-error

Question

I can't find out why my program doesn't work.
It works normal without "a = 5;" in program for parse(it is block of code below)
%{
#include <iostream>
int line_count = 0;
#include "translator.h"
%}
%union
{
Stmt *separator;
Expr *exp;
Stmt *statement;
int int_val;
char name[256];
};
%token <int_val> NUM
%token <name> ID
%token STRING ENDLINE BOOLEAN INT MAIN PUBLIC CLASS VOID STATIC PRINTLN EQ
%start programm
%type <separator> separator
%type <statement> statement
%type <statement> assign_statement
%type <exp> exp
%type <exp> var_ref
%type <exp> literal_exp
%left EQ
%%
programm:
class_declaration
;
class_declaration:
PUBLIC CLASS ID opencurlybracket main_method_declaration closecurlybracket
;
main_method_declaration:
PUBLIC STATIC VOID MAIN '(' STRING '[' ']' ID ')' opencurlybracket method_body closecurlybracket
;
method_body:
local_declarations
|
statements
;
statements:
statement
|
statements statement
;
statement:
assign_statement
;
assign_statement:
var_ref '=' exp ';' separator { $$ = new StmtAssign($1, $3); }
;
local_declarations:
local_declaration
|
local_declarations local_declaration
;
local_declaration:
type ID ';' separator
;
exp:
var_ref
|
literal_exp
;
var_ref:
ID { $$ = new ExprVar($1); }
;
literal_exp:
NUM { $$ = new ExprNum($1); }
;
type:
INT
|
BOOLEAN
;
separator:
ENDLINE
{
++line_count;
$$ = new StmtEndline(line_count);
}
;
opencurlybracket:
'{'
|
'{' separator
;
closecurlybracket:
'}'
|
'}' separator
;
%%
Code for parsing by this grammar:
public class Summ {
public static void main(String[] args) {
int a;
a = 5;
}
}
And lex file:
%{
#include <stdlib.h>
#include <stdio.h>
#include "translator.h"
%}
%option noyywrap
%%
(public) { return (PUBLIC); }
(class) { return (CLASS); }
(static) { return (STATIC); }
(void) { return (VOID); }
(main) { return (MAIN); }
(String) { return (STRING); }
(int) { return (INT); }
(println) { return (PRINTLN); }
(\{) { return '{'; }
(\}) { return '}'; }
(\() { return '('; }
(\)) { return ')'; }
(\[) { return '['; }
(\]) { return ']'; }
(\;) { return ';'; }
(\=) { return '='; }
"==" { return (EQ); }
(\n) { return (ENDLINE); }
[a-zA-Z_\$][a-zA-Z0-9_\$]* {
printf("found %s\n", yytext);
strcpy(yylval.name, yytext);
return ID;
}
([0])|([1-9][0-9]*) {
printf("found %s\n", yytext);
yylval.int_val = atoi(yytext);
return NUM;
}
" " { /*space - do nothing*/ }
. { /*do nothing*/ }
%%
I hope that someone find bug in my code.

Answer 1

Here's your definition of method_body:
method_body:
local_declarations
|
statements
;
This specifies that a method_body contains either local_declarations or statements, but not both. You need to change it to accept local_declarations followed by statements.