To sum values from multipile workbooks with multiple worksheets - vba

Question

I have multiple workbooks with multiple worksheets.I wrote a code in a newworkbook.All the workbooks have the same format.I need to do sum in a new workbook for multiple cells .Please help me with a code.I got a subscript out of range error.I dont have any experince of coding.
Private Sub Intra_Group_Exp1()
Dim i As Integer
Dim fileName As String
Const FOLDER As String = "C:\Sushant_Files\"
On Error GoTo ErrorHandler
fileName = Dir(FOLDER, vbDirectory)
Do While Len(fileName) > 0
If Right$(fileName, 4) = "xlsx" Or Right$(fileName, 3) = "xls" Then
i = i + 1
Dim currentWkbk As Excel.Workbook
Set currentWkbk = Excel.Workbooks.Open(FOLDER & fileName)
Dim P As Integer
Dim q As Integer
For P = 10 To 32
For q = 2 To 19
ThisWorkbook.Worksheets("Intra Group_Exp").Cells("p,q").Value = ThisWorkbook.Worksheets("Intra Group_Exp").Cells("p,q").Value + currentWkbk.Sheets("Intra Group_Exp").Cells("p,q:p,q").Value
Next q
Next P
currentWkbk.Close
End If
fileName = Dir
Loop
ProgramExit:
Exit Sub
ErrorHandler:
MsgBox Err.Number & " - " & Err.Description
Resume ProgramExit
End Sub

Answer 1

Your main error is the following: You should address cells like worksheet.Cells(p, q) instead of worksheet.Cells("p, q"). The latter passes over the string p, q and not the content of the variables!
Having said this, it's much better to simple use .PasteSpecial with the options Values and Add. See this post
So give this code a try:
Option Explicit
Private Sub Intra_Group_Exp1()
Const FOLDER As String = "C:\Sushant_Files\"
Const cStrWSName As String = "Intra Group_Exp"
Const cStrRangeAddress As String = "B10:S32"
Dim rngTarget As Range
Dim wbSource As Workbook
Dim fileName As String
On Error GoTo ErrorHandler
Application.ScreenUpdating = False
Application.Calculation = xlCalculationManual
Set rngTarget = ThisWorkbook.Worksheets(cStrWSName).Range(cStrRangeAddress)
fileName = Dir(FOLDER, vbDirectory)
Do While Len(fileName) > 0
If Right$(fileName, 4) = "xlsx" Or Right$(fileName, 3) = "xls" Then
Set wbSource = Workbooks.Open(FOLDER & fileName)
wbSource.Worksheets(cStrWSName).Range(cStrRangeAddress).Copy
rngTarget.PasteSpecial xlPasteValues, xlPasteSpecialOperationAdd
wbSource.Close
End If
fileName = Dir
Loop
ProgramExit:
Application.ScreenUpdating = True
Application.Calculation = xlCalculationAutomatic
Exit Sub
ErrorHandler:
MsgBox Err.Number & " - " & Err.Description
Resume ProgramExit
End Sub
As you can see, I added a few other improvements, hope it helps! :-)