VB Loop for MS Access that adds numbers - sql

Question

I'm new to coding with Access. I'm wanting to create a Do While Until loop that compares the amounts of two tables. One table has a record with customer numbers with the total amount for each customer number and then another table that has all detail line items with amounts for the items for each customer.
Example:
Summary
CustID | Total |
1234 | $20.00 |
2345 | $40.00 |
Detail
CustID | DocNo | Amount | Included |
1234 | 0000 | $15.00 | |
1234 | 1111 | $5.00 | |
1234 | 2222 | $3.00 | |
I wanted to be able to execute the loop and then update the Included column to "Yes" to all applicable line items whose accumulated sum added to the total in the Summary table.
So the example above would update the first and second rows of the Detail table to "Yes" and then move on to the next CustID, because the first two row Amounts totaled to $20.00 - the amount in the Summary table. The last record in the detail table will not be updated to anything, because it does not apply. The good thing about the order of these records is that the records that will be labeled "Yes" will be the first cumulative set of records; not every other record, or random records. There are no fixed number of records for each total, it varies - therefore, I need the loop.
Also, does anyone have a recommendation for how to best learn VB/VBA for Access and Excel? I only understand SQL and I'm trying to enhance my coding skills, so I'm not having to manually subtotal these amounts and then delete the 30,000 non applicable records in an Excel spreadsheet.
Thanks in advance!

Answer 1

I've worked out a first approach, using DAO, your tables are supposed to be Summary and Detail:
Sub sof20295931SummaryDetail()
Dim lCustID0 As Long
Dim dblDetailTotal As Double, dblSummaryTotal As Double
Dim strSQL As String
Dim rst0 As DAO.Recordset, rst As DAO.Recordset
'
' get summary recordset:
'
strSQL = "SELECT CustID, Total" _
& " FROM Summary" _
& " ORDER BY CustID;"
Set rst0 = CurrentDb.OpenRecordset(strSQL)
'
' get detail recordset:
'
strSQL = "SELECT CustID, DocNo, Amount, Included" _
& " FROM Detail" _
& " ORDER BY CustID,DocNo;"
Set rst = CurrentDb.OpenRecordset(strSQL)
lCustID0 = rst0!CustID
dblSummaryTotal = rst0!Total
dblDetailTotal = 0
'
' check the recordset of the Detail:
'
Do While (Not rst.EOF)
'
' change CustID:
'
If (rst!CustID > lCustID0) Then
rst0.MoveNext
lCustID0 = rst0!CustID
dblSummaryTotal = rst0!Total
dblDetailTotal = 0
End If
'
' sum up:
'
dblDetailTotal = dblDetailTotal + rst!amount
'
' modify record:
'
rst.Edit
'
If (dblDetailTotal <= dblSummaryTotal) Then
rst!Included = "Yes"
Else
rst!Included = Null
End If
'
rst.Update
'
' go to the next record:
'
rst.MoveNext
Loop
'
' destruct objects:
'
rst0.Close
Set rst0 = Nothing
'
rst.Close
Set rst = Nothing
End Sub
My Windows Locale used Euro Money format, here is the Summary table:
And Detail table in which I added some extra records:
Detail after modification:

Answer 2

Since no reply on whether a more SQL-centered approach is okay, here it is.
The field Included does not logically belong in Detail, but in Summary. If you want to keep it in Detail, using SQL is a challenge: you can't use the aggregate function Sum() and also update values. But if you move Included to Summary, SQL is the natural solution. I would recommend this approach.
qrySummary (to be nested in second query below)
SELECT CustID, Sum([Total]) AS CustomerTotal
FROM tblDetail GROUP BY CustID;
qryValidate
UPDATE tblSummary LEFT JOIN qrySummary ON tblSummary.CustID = qrySummary.CustID
SET tblSummary.Included =
IIf([qrySummary].[CustomerTotal]=[tblSummary].[Amount],True,False);
To follow through on the spreadsheet, you will need to view Included at the detail level; this will require a query that joins Detail and Summary.