multiple recipients email mismatch in VBA - vba

Question

I am trying to add multiple recipients' emails that are on a range of cells.
I am able to select the range of emails on the sheet.
However, I kept getting this mismatch error and I have no idea how to solve it.
I have been looking around for solutions and did the same steps.
Please pardon me, i am new to VBA.
I would very much appreciate your help.
My code is below,
Private Sub CommandButton1_Click()
Dim olapp As Object
Dim olmail As Object
Dim recip As String
lastr = ThisWorkbook.Sheets("Sheet1").Cells(Rows.Count, 1).End(xlUp).Row
'this is for the range of data to be copied on the body but have yet to do it
lastr2 = ThisWorkbook.Sheets("Sheet1").Cells(Rows.Count, 7).End(xlUp).Row
recip = ThisWorkbook.Sheets("Sheet1").Range("G3:G" & lastr2).Value
'mismatch after this step
Set olapp = CreateObject("Outlook.Application")
Set olmail = olapp.CreateItem(0)
With MItem
.to = recip
.Subject = "hello"
.Body = "whats up"
.display
End With
Any idea why is this happening?

Answer 1

You're trying to assign an array (a range of multiple cells is an Array) to a string variable. WIthout testing, I know you can resolve this with a For Each loop, as Jaycal's comment suggested:
Dim cl as Range
For each cl in ThisWorkbook.Sheets("Sheet1").Range("G3:G" & lastr2).Cells
recip = recip & ";" & cl.Value
Next
But you could simplify by using the string Join function. The Join function effectively performs this loop on an array of strings, so it saves you an unnecessary loop. I modify to use a range variable for legibility:
Dim sendRange as Range
Set sendRange = ThisWorkbook.Sheets("Sheet1").Range("G3:G" & lastr2)
recip = Join(Application.Transpose(sendRange.Value), ";")
Whichever method you use, you will be able to use the same With block.
With MItem
.to = recip
.Subject = "hello"
.Body = "whats up"
.display
End With