De-Replicate an Access Database - ms-access-2007

Question

I have an Access database that I need to reverse engineer into a website (app & data).
I just tried opening it with Outlook 2013 but I get an error that the database has replication enabled and it created with an earlier version of Access (something to that affect).
I assume it's just the replication that's the issue. Is there a way to remove the replication so I can poen it in Access 2013?

Answer 1

So it's not an easy job to unreplicate a database.
First I found WV Mitchell's VBA script that copies your tables into a new database:
http://www.wvmitchell.com/tips/Removing%20Access%20Replication.htm
That doesn't copy the Primary Keys or the Relationships, so I wrote a few quick and dirty VBA scripts to help with that.
Step 1: In the MakeOneTable function from the above script, I added this (above the db.Close line):
Dim td As TableDef
Dim idxLoop As Index
Set td = db.TableDefs(TableName)
For Each idxLoop In td.Indexes
If idxLoop.Primary = True Then
Dim colnames As String
colnames = idxLoop.Fields
colnames = Replace(colnames, ";+", "],[")
colnames = Replace(colnames, "+", "[")
colnames = colnames & "]"
Debug.Print "DoCmd.RunSQL ""CREATE INDEX [PrimaryKey] ON [" & TableName & "] (" & colnames & ") With Primary;"""
Exit For
End If
Next idxLoop
That will output to the Debug (Immediate) Window some VBA code for creating the primary keys (as well as creating the new database and exporting the data to it - MV Mitchell's code). Copy that VBA code, put it into a module/macro in the new database, and run it - and it should create the Primary Keys.
Step 2: In the Old (replicated) database, run this VBA code, which will generate some more VBA code for creating the relationships:
Sub GenerateRelationshipCode()
Dim db As DAO.Database
Set db = CurrentDb()
Dim rs As DAO.Recordset
Set rs = db.OpenRecordset("SELECT DISTINCT szRelationship,szObject,szReferencedObject FROM MSysRelationships ORDER BY szObject,szReferencedObject")
rs.MoveFirst
Do While Not rs.EOF
Dim rsFields As DAO.Recordset
Set rsFields = db.OpenRecordset("SELECT * FROM MSysRelationships WHERE szRelationship = '" & Replace(rs.Fields(0), "'", "''") & "'")
Dim PKFields As String, PKTable As String, FKFields As String, FKTable As String
PKFields = "": PKTable = "": FKFields = "": FKTable = ""
Do While Not rsFields.EOF
PKFields = PKFields & rsFields("szReferencedColumn") & ","
PKTable = rsFields("szReferencedObject")
FKFields = FKFields & rsFields("szColumn") & ","
FKTable = rsFields("szObject")
rsFields.MoveNext
Loop
PKFields = Left(PKFields, Len(PKFields) - 1)
FKFields = Left(FKFields, Len(FKFields) - 1)
Debug.Print "Call AddRelationship(""" & rs.Fields(0) & """, """ & FKTable & """, """ & FKFields & """, """ & PKTable & """, """ & PKFields & """)"
rs.MoveNext
Loop
Set db = Nothing
End Sub
You will need to run the output from the above against the new database, but you will also need this function:
Public Sub AddRelationship(Name As String, FKTable As String, FKFields As String, PKTable As String, PKFields As String)
Dim strSQL As String
Dim db As DAO.Database
Set db = CurrentDb()
Name = "FK_" & Replace(FKTable, " ", "") & "_" & Replace(PKTable, " ", "") 'only enable this line if there aren't multiple relationships between same 2 tables
strSQL = "ALTER TABLE [" & FKTable & "] " & _
" add constraint " & Name & " foreign key (" & FKFields & ") " & _
" references [" & PKTable & "](" & PKFields & ") "
db.Execute strSQL, dbFailOnError
Set db = Nothing
End Sub
Run the generated VBA code in a module with the above function, and it should rebuild your relationships in the new database.
Note this code is quick & dirty so might need some bug fixes for your database/data.