how to delay text to speech code on textboxes visual basic 2010 - vb.net

Question

Im trying to make my visual basic code speak multiple text boxes with a delay of 30 seconds between each textbox, so far i have:
Public Class Form1
Private Sub Button1_Click(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles Button1.Click
If OpenFileDialog1.ShowDialog() = DialogResult.OK Then
End If
If My.Computer.FileSystem.FileExists(OpenFileDialog1.FileName) Then
Dim ioFile As New System.IO.StreamReader(OpenFileDialog1.FileName)
TextBox1.Text = ioFile.ReadLine()
TextBox2.Text = ioFile.ReadLine()
TextBox3.Text = ioFile.ReadLine()
TextBox4.Text = ioFile.ReadLine()
TextBox5.Text = ioFile.ReadLine()
TextBox6.Text = ioFile.ReadLine()
TextBox7.Text = ioFile.ReadLine()
TextBox8.Text = ioFile.ReadLine()
TextBox9.Text = ioFile.ReadLine()
TextBox10.Text = ioFile.ReadLine()
End If
End Sub
Private Sub Button2_Click(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles Button2.Click
Dim SAPI
SAPI = CreateObject("SAPI.spvoice")
SAPI.Speak(TextBox1.Text)
End Sub
End Class
Basically i have 10 text boxes that have 10 words in them (loaded form a txt file) and i have a txt to speech code saying the first textbox but i want that text to speech code linked to button 2 to say all the textboxes with a 30 second delay between each textbox, how would i go about doing this?

Answer 1

For this to work you probably want a multithreaded application. However if you don't a quick and dirty way of making it would would be:
system.threading.thread.sleep(30000)
But then the UI would lock up. So you really want this running on a different thread. A timer is the easiest way to implement this. Just have the timer.tick value set to 30,000. When button 2 is pressed have it create an array with all the textbox strings in. The have a global variable (integer). Each time the timer is ticked it speaks the text in the array at the ndex of the global variable, then increment the global variable!
http://msdn.microsoft.com/en-us/library/system.timers.timer(v=vs.110).aspx

Answer 2

Here's an example using a BackgroundWorker() and an Enumerator built from the words in the TextBoxes:
Public Class Form1
Private Sub Button1_Click(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles Button1.Click
If OpenFileDialog1.ShowDialog() = DialogResult.OK Then
Dim matches() As Control
Dim lines() As String = System.IO.File.ReadAllLines(OpenFileDialog1.FileName)
For i As Integer = 1 To 10
matches = Me.Controls.Find("TextBox" & i, True)
If matches.Length > 0 AndAlso TypeOf matches(0) Is TextBox Then
If i <= lines.Count Then
DirectCast(matches(0), TextBox).Text = lines(i - 1)
Else
DirectCast(matches(0), TextBox).Text = ""
End If
End If
Next
End If
End Sub
Private Sub Button2_Click(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles Button2.Click
If Not BackgroundWorker1.IsBusy Then
Dim words As New List(Of String)
Dim matches() As Control
For i As Integer = 1 To 10
matches = Me.Controls.Find("TextBox" & i, True)
If matches.Length > 0 AndAlso TypeOf matches(0) Is TextBox Then
Dim TB As TextBox = DirectCast(matches(0), TextBox)
If TB.Text.Trim <> "" Then
words.Add(TB.Text.Trim)
End If
End If
Next
If words.Count > 0 Then
BackgroundWorker1.RunWorkerAsync(words.GetEnumerator)
End If
End If
End Sub
Private Sub BackgroundWorker1_DoWork(sender As System.Object, e As System.ComponentModel.DoWorkEventArgs) Handles BackgroundWorker1.DoWork
Dim SAPI = CreateObject("SAPI.spvoice")
Dim wordsEnum As IEnumerator(Of String) = DirectCast(e.Argument, IEnumerator(Of String))
While wordsEnum.MoveNext
SAPI.Speak(wordsEnum.Current)
System.Threading.Thread.Sleep(TimeSpan.FromSeconds(30).TotalMilliseconds)
End While
End Sub
Private Sub BackgroundWorker1_RunWorkerCompleted(sender As Object, e As System.ComponentModel.RunWorkerCompletedEventArgs) Handles BackgroundWorker1.RunWorkerCompleted
MessageBox.Show("Done!")
End Sub
End Class