Applescript Errors with Mail - error-handling

Question

I made this quick Applescript application and it gave me an error, here is the coding:
set buyannounce to "AUTOMATIC SERVER EMAIL : BUY"
set transferannounce to "AUTOMATIC SERVER EMAIL : TRANSFER"
set signupannounce to "AUTOMATIC SERVER EMAIL : SIGNUP"
set sellannounce to "AUTOMATIC SERVER EMAIL : SELL"
set nowsignup to "0"
set announce to "AUTOMATIC SERVER EMAIL"
set ¬
currentSignups ¬
to the text returned ¬
of (display dialog ¬
¬
"How many current signups?" default answer "")
tell application "Mail"
set unreadMessages to (get every message of mailbox "INBOX" of account "Yahoo" whose read status is true)
repeat with eachMessage in unreadMessages
if announce is in (get content of eachMessage) then
if buyannounce is in (get content of eachMessage) then
--buy email
end if
if transferannounce is in (get content of eachMessage) then
--transfer email
end if
if signupannounce is in (get content of eachMessage) then
set nowsignup to nowsignup + 1
set eachMessageTrimmed to ((characters 33 thru -1 of (get content of eachMessage)) as string)
display dialog nowsignup
set filepath to POSIX path of "/Users/obleopold/Dropbox/Accounts.csv"
try
set command to "open " & quoted form of filepath
do shell script command
end try
delay 10
repeat currentSignups times
tell "System Events" to keystroke return
end repeat
repeat nowsignup times
tell "System Events"
keystroke eachMessageTrimmed --here is where I am getting the error
end tell
tell "System Events" to keystroke return
currentSignups = currentSignups + nowsignup
set nowsignup to "0"
end repeat
end if
if sellannounce is in (get content of eachMessage) then
--sell email
end if
end if
end repeat
end tell
end
end
end
end

Answer 1

I did not check if your code works properly but here's one way to write your code to avoid the problems. You can use subroutines. When you call a subroutine from within a "tell" block of code you need to preface it with the word "my". This tells the script that the subroutine belongs to the script and not the application you are telling.
Notice that you can optimize your code by getting the message content once. Every time you "get content of eachMessage" there's a performance hit... so do it only once. Notice also that I added some delays between your keystroke commands. Normally you need these small delays to prevent errors when you are doing things like this. It gives your computer a little extra time to perform the keystrokes.
Good luck.
set buyannounce to "AUTOMATIC SERVER EMAIL : BUY"
set transferannounce to "AUTOMATIC SERVER EMAIL : TRANSFER"
set signupannounce to "AUTOMATIC SERVER EMAIL : SIGNUP"
set sellannounce to "AUTOMATIC SERVER EMAIL : SELL"
set nowsignup to "0"
set announce to "AUTOMATIC SERVER EMAIL"
set currentSignups to the text returned of (display dialog "How many current signups?" default answer "")
tell application "Mail"
set unreadMessages to (get every message of mailbox "INBOX" of account "Yahoo" whose read status is true)
repeat with eachMessage in unreadMessages
set messageContent to content of eachMessage
if announce is in messageContent then
if buyannounce is in messageContent then
--buy email
end if
if transferannounce is in messageContent then
--transfer email
end if
if signupannounce is in messageContent then
set nowsignup to nowsignup + 1
set eachMessageTrimmed to my trimMessageText(messageContent)
display dialog nowsignup
my openFilePath(POSIX path of "/Users/obleopold/Dropbox/Accounts.csv")
delay 10
repeat currentSignups times
my keystrokeSomething(return)
delay 0.2
end repeat
repeat nowsignup times
my keystrokeSomething(eachMessageTrimmed)
delay 0.2
my keystrokeSomething(return)
delay 0.2
currentSignups = currentSignups + nowsignup
set nowsignup to "0"
end repeat
end if
if sellannounce is in messageContent then
--sell email
end if
end if
end repeat
end tell
(************* SUBROUTINES *****************)
on trimMessageText(messageText)
try
return text 33 thru -1 of messageText
on error
return messageText
end try
end trimMessageText
on keystrokeSomething(something)
tell application "System Events"
keystroke something
end tell
end keystrokeSomething
on openFilePath(filepath)
try
do shell script "open " & quoted form of filepath
end try
end openFilePath
The other way to separate your tell blocks would be something like this. But in your case it seems subroutines are easier.
tell application "Mail"
-- do something
end tell
set eachMessageTrimmed to text 33 thru -1 of messageText
tell application "System Events"
-- do something
end tell
do shell script "something"
tell application "Mail"
-- do something
end tell

Answer 2

System Events is an application, so for your tell blocks you need
tell application "System Events"
Instead of
tell "System Events"
Furthermore, to prevent nested tell blocks you can use:
tell application "System events"
tell process "Mail"
keystroke "My Keystroke"
end tell
end tell
Or in one line:
tell application "System Events" to tell process "Mail" to keystroke "My Keystroke"