Highlighting duplicates column by column - vba

Question

I'm trying to go go through columns and highlight duplicates within the columns.
I used record macro to get an idea of what I need but I'm not sure how to apply this across many columns. Highlighting all columns won't work because many of the names repeat. I need to find out if a name repeats multiple times within a list.
This is the code I have so far:
Sub findDuplicates()
Application.Goto Reference:="R3C18:R89C18"
Application.Goto Reference:="R3C18:R88C18"
Selection.FormatConditions.AddUniqueValues
Selection.FormatConditions(Selection.FormatConditions.Count).SetFirstPriority
Selection.FormatConditions(1).DupeUnique = xlDuplicate
With Selection.FormatConditions(1).Font
.Color = -16751204
.TintAndShade = 0
End With
With Selection.FormatConditions(1).Interior
.PatternColorIndex = xlAutomatic
.Color = 10284031
.TintAndShade = 0
End With
Selection.FormatConditions(1).StopIfTrue = False
Range("R21").Select
End Sub
This is code I have that goes through each column within my range from B3:OA3 and sorts by color and alphabet. My thinking is that because this code goes column by column and sorts, I could simply add to it to highlight duplicates within the column it was already sorting. But I'm not sure how'd I'd do that.
Sub sortColorThenAlpha()
'sort by color then by alphabet
Dim rngFirstRow As Range
Dim rng As Range, rngSort As Range
Dim ws As Worksheet
Application.ScreenUpdating = False
Set ws = ActiveSheet
Set rngFirstRow = ws.Range("B3:OA3")
For Each rng In rngFirstRow.Cells
With ws.Sort
Set rngSort = rng.Resize(86, 1) 'to row 88
.SortFields.Clear
.SortFields.Add(rng, xlSortOnCellColor, xlAscending, , xlSortNormal). _
SortOnValue.Color = RGB(198, 239, 206)
.SortFields.Add Key:=rng, SortOn:=xlSortOnValues, _
Order:=xlAscending, DataOption:=xlSortNormal
.SetRange rngSort
.Header = xlNo
.MatchCase = False
.Orientation = xlTopToBottom
.SortMethod = xlPinYin
.Apply
End With
Next rng
Application.ScreenUpdating = True
End Sub
This is what I'm looking at. That yellow conditinal formatting is what I'm trying to apply to each column between row 3 and 88.

Answer 1

VBA does not seem necessary as Conditional Formatting with the following rules seems to work:
=A1=VLOOKUP(A1,A2:A$99,1,FALSE) Applies to: =$A$1:$J$99
=A2=VLOOKUP(A2,A$1:A1,1,FALSE) Applies to: =$A$2:$J$99
with references adjusted to suit.

Answer 2

If I understand your question correctly, you want to be able to highlight duplicates in a single column, and you want to be able to automatically apply this formatting to all columns in a given sheet. So if Cleopatra appears once in several columns, she won't be highlighted, but if she appears more than once in a single column, she will.
The following code does just that. I'm finding the last column by looking for a value in row 3.
Sub HighlightDupesOneColumnAtATime()
Dim ws As Worksheet
Dim myColumn As Long
Dim i As Integer
Dim columnCount As Long
Dim lastRow As Long
Dim dupeColor As Long
Set ws = ThisWorkbook.Sheets("Sheet1")
columnCount = ws.Cells(3, ws.Columns.Count).End(xlToLeft).Column
dupeColor = 9944516
For i = 1 To columnCount
lastRow = ws.Cells(ws.Rows.Count, i).End(xlUp).Row
Call HighlightDupesInRange(dupeColor, Cells(1, i).Resize(lastRow, 1))
' it is easy to change the color of the
' highlighted duplicates if you want
dupeColor = dupeColor + 15
Next i
End Sub
Sub HighlightDupesInRange(cellColor As Long, rng As Range)
With rng
.FormatConditions.Delete
.FormatConditions.AddUniqueValues
.FormatConditions(1).DupeUnique = xlDuplicate
.FormatConditions(1).Interior.Color = cellColor
.FormatConditions(1).StopIfTrue = False
End With
End Sub