Keep checked items checked while searching in CheckedListBox - vb.net

Question

I'm having some problems with VB.
I'm trying to create code that will keep the checked items in a CheckedListBox while you search through it. I have an array that stores the names of the checked items, but when you use the CkeckedListBox.SetCheckedItem() method, you need to use indices, and those change every time I search in the list box.
This is what I have so far:
Dim checkeditems(1000) As String
If txtSearch.Text.Length = 1 Then
For i = 0 To 1000
If lstVerktyg.CheckedItems.Item(i) = "" Then
Exit For
End If
checkeditems(i) = lstVerktyg.CheckedItems.Item(i)
Next
End If
Dim Connection As New MySqlConnection("server=" & My.Settings.Host & ";user id=" & My.Settings.User & "; password=" & My.Settings.Pass & "; port=3306; database=" & My.Settings.DB & "; pooling=false")
Try
Connection.Open()
Catch ex As MySqlException
Exit Sub
End Try
Dim Reader As MySqlDataReader
Dim Query As MySqlCommand
Dim ResultsNumber As Integer = 0
lstVerktyg.Items.Clear()
Query = New MySqlCommand("SELECT `namn` FROM `verktyg` WHERE `namn` LIKE '%" & txtSearch.Text.Replace("'", "\'") & "%' LIMIT 300;", Connection)
Reader = Query.ExecuteReader()
While (Reader.Read())
lstVerktyg.Items.Add(Reader.GetString("namn"))
End While
If Reader IsNot Nothing Then Reader.Close()
For i = 0 To 1000
If checkeditems(i) = "" Then
Exit For
End If
If lstVerktyg.GetItemChecked(i) Then
End If
Next
What do I do?

Answer 1

Here is a simple example of how you can do that. Let's say you initially fill a CheckedListBox control with some items, like this:
CheckedListBox1.Items.AddRange({"Item 1", "Item 2", "Item 3"})
Then, you show the form and let the user check whatever items they choose. Then, when you want to reload the list and retain which items are checked, you can do it like this. First, you want to create a list of all the checked items:
Dim checkedItems As New List(Of Object)(CheckedListBox1.CheckedItems.Count)
For Each i As Object In CheckedListBox1.CheckedItems
checkedItems.Add(i)
Next
Then, you can safely clear the items from the CheckedListBox:
CheckedListBox1.Items.Clear()
Then, you can reload the list with refreshed data, for instance:
CheckedListBox1.Items.AddRange({"Item 1", "Item 2", "Item 3", "Item 4"})
Then, you can loop through the items in the CheckedListBox and check each one if it exists in the saved list of checked items:
For i As Integer = 0 To CheckedListBox1.Items.Count - 1
If checkedItems.Contains(CheckedListBox1.Items(i)) Then
CheckedListBox1.SetItemChecked(i, True)
End If
Next
So, to apply that method to your code example, it would look something like this:
Dim checkedItems As New List(Of Object)(lstVerktyg.CheckedItems.Count)
If txtSearch.Text.Length = 1 Then
For Each i As Object In lstVerktyg.CheckedItems
If i = "" Then Exit For
checkedItems.Add(i)
Next
End If
Dim Connection As New MySqlConnection("server=" & My.Settings.Host & ";user id=" & My.Settings.User & "; password=" & My.Settings.Pass & "; port=3306; database=" & My.Settings.DB & "; pooling=false")
Try
Connection.Open()
Catch ex As MySqlException
Exit Sub
End Try
Dim Reader As MySqlDataReader
Dim Query As MySqlCommand
Dim ResultsNumber As Integer = 0
lstVerktyg.Items.Clear()
Query = New MySqlCommand("SELECT `namn` FROM `verktyg` WHERE `namn` LIKE '%" & txtSearch.Text.Replace("'", "\'") & "%' LIMIT 300;", Connection)
Reader = Query.ExecuteReader()
While (Reader.Read())
lstVerktyg.Items.Add(Reader.GetString("namn"))
End While
If Reader IsNot Nothing Then Reader.Close()
For i As Integer = 0 To lstVerktyg.Items.Count - 1
If checkedItems.Contains(lstVerktyg.Items(i)) Then
lstVerktyg.SetItemChecked(i, True)
End If
Next