Coldfusion/SQL: Element Id is not defined in form - sql

Question

When I attempt to delete an item in a shopping cart. I get a "Element Id is not defined in form" error.
Where am I going wrong?
I'm using MSSQL 2008 r2, Coldfusion 10.
Summary:
tickets.cfm this is the page that displays the products, also contains a form with hidden values to be passed on to cart_manage.cfm.
cart_manage.cfm is an action page for both tickets.cfm and cartlist.cfm
cartlist.cfm is a page that displays the shopping cart contents.
application.cfm session variables.
application.cfm
<cfapplication sessionmanagement="yes">
<cfapplication name="cart" clientmanagement="Yes"
sessionmanagement="Yes"
sessiontimeout="#CreateTimeSpan(0,0,15,0)#"
applicationtimeout="#CreateTimeSpan(0,2,0,0)#">
<cfparam name="session.allowin" default="false">
tickets.cfm
<cfif NOT IsDefined('SESSION.cart')>
<cfset SESSION.cart = ArrayNew(1) />
</cfif>
<cfquery datasource="sqltest" name="getTickets">
select *,
CASE WHEN Friday=1and Saturday=1and Sunday=1
THEN 'All three days'
WHEN Friday=0and Saturday=0and Sunday=0
THEN 'None'
ELSE
STUFF(
case when Friday=1 then ',Friday' else '' end
+ case when Saturday=1 then ',Saturday' else '' end
+ case when Sunday=1 then ',Sunday' else '' end, 1,1,'')
END WhichDays
from tickets_performances;
</cfquery>
<table width="600" border="0">
<tr>
<td>Day</td>
<td>Price</td>
<td>How Many Left</td>
<td>Quantity</td>
</tr>
<p> You can only purchase a maximum of two tickets at a time. Having a ticket limit ensures fairness to all those buying tickets. The ticket limit applies per account, billing address, and/or credit card. Please observe the ticket limit as over purchases may be cancelled without notice or warning. </p>
<cfform action="cart_manage.cfm" name="form" method="post">
<cfoutput query="getTickets">
<tr>
<td>#WhichDays#</td>
<td>£#price#</td>
<td>#stock#</td>
<td><cfinput type="text" id="quantity" name="quantity" size="5" class="field" maxlength="1" value="0"/></td>
<td><cfinput type="hidden" name="id" value="#getTickets.ticket_performanceID#" />
<cfinput type="hidden" name="item" value="#getTickets.WhichDays#" />
<cfinput type="hidden" name="price" value="#getTickets.price#" />
<cfinput type="submit" name="add_button" value="Add to Cart"></td>
</tr>
</cfoutput>
</cfform>
</table>
cart_manage.cfm
<cfset newitem = 0>
<cfloop from="1" to="#arrayLen(session.cart)#" index="i">
<cfif session.cart[i].itemid EQ #form.id#>
<cfset session.cart[i].quantity = session.cart[i].quantity + #form.quantity#>
<cfset newitem = 1>
<cfbreak>
</cfif>
</cfloop>
<cfif newitem EQ 0>
<cfset temp = arrayAppend(session.cart, structNew())>
<cfset session.cart[arrayLen(session.cart)].itemid = #form.id#>
<cfset session.cart[arrayLen(session.cart)].item = #form.item#>
<cfset session.cart[arrayLen(session.cart)].quantity = #form.quantity#>
<cfset session.cart[arrayLen(session.cart)].price = #form.price#>
<cflocation url="cartlist.cfm">
</cfif>
<cfif IsDefined('FORM.delete_button.y')>
<cfloop from="#ListLen(FORM.delete_index)#" to="1" index="i" step="-1">
<cfset ArrayDeleteAt(SESSION.cart, ListGetAt(FORM.delete_index, i))>
</cfloop>
<cflocation url="cartlist.cfm">
<cfelseif IsDefined('FORM.update_button.y')>
<cfloop from="1" to="#ArrayLen(SESSION.cart)#" index="i">
<cfset SESSION.cart[i].quantity = FORM["quantity_" & i] >
</cfloop>
<cflocation url="cartlist.cfm">
<cfelseif IsDefined('FORM.checkout_button.y')>
<cflocation url="checkout.cfm">
</cfif>
<cflocation url="cartlist.cfm">
cartlist.cfm
<cfset nTotal = 0 />
<cfform action="cart_manage.cfm" method="post">
<table width="100%">
<tr valign="top">
<td>
<table width="100%" class="white">
<tr>
<td class="tblehead"> </td>
<td class="tblehead">Item</td>
<td class="tblehead">Price Per Item</td>
<td class="tblehead">Quantity</td>
<td class="tblehead">Price</td>
</tr>
<cfoutput>
<cfloop from="1" to="#ArrayLen(SESSION.cart)#" index="i">
<tr>
<td height="40" width="40" align="center" class="dkturq">
<cfinput type="checkbox" name="delete_index" value="#i#" />
</td>
<td height="40" class="dkturq">
#SESSION.cart[i].item#
</td>
<td height="40" class="dkturq">
£#(SESSION.cart[i].price)#
</td>
<td height="40" class="dkturq">
<cfinput type="text" name="quantity_#i#" value="#SESSION.cart[i].quantity#" size="5" class="field" />
</td>
<td height="40" class="dkturq">
<cfset nPrice = SESSION.cart[i].quantity * SESSION.cart[i].price />
<cfset nTotal = nTotal + nPrice />
£#(nPrice)#
</td>
</tr>
</cfloop>
</cfoutput>
</table>
</td>
<td></td>
<td>
<table width="100%" height="100%" class="white">
<tr>
<td class="tblehead">
Summary
</td>
</tr>
<tr>
<td class="dkturq">
total:
<cfoutput>£#(nTotal)#</cfoutput>
<br /><br /><br /><br />
Clear Shopping Cart
<cfinput type="submit" name="update_button" id="update_button" value="update" />
<cfinput type="submit" name="delete_button" id="delete_button" value="delete" /><br /></a>
</td>
</tr>
</table>
</td>
</tr>
</table>
</cfform>
CFDUMP of FORM
CFDUMP of Session.cart
Error:
CFDUMP when I press delete

Answer 1

Thanks to Leigh, I managed to get it to work.
(Summary from the chat ..)
The original problem is pretty much what the error message said. ie Trying to use a form field that does not exist. The cause is "tickets.cfm" and "cartList.cfm" contain different form fields. The form in "cartList.cfm" does not contain a field named form.id, hence the error when that form is submitted. To avoid the error you need to verify the form.id exists, with structKeyExists() before accessing it.
However, we decided to revise the action page code instead. Also, the "cartList.cfm" form was changed to use itemID instead of index. Reason being, the index can change which might cause the wrong item to be deleted or updated. There is still room for improvement, but here is the jist of the changes:
*cartList.cfm (form fields) *
<!--- use itemID's instead of "index" in all form fields --->
<cfinput type="checkbox" name="delete_itemID" value="#SESSION.cart[i].itemid#" />
<cfinput type="text" name="quantity_#SESSION.cart[i].itemid#" value="#SESSION.cart[i].quantity#" size="5" class="field" /><br>
cartManage.cfm
<!--- ADD item to cart ---->
<cfif structKeyExists(FORM, "add_button")>
... code to add items here ...
<!--- DELETE from cart ---->
<cfelseif structKeyExists(FORM, "delete_button")>
<!---
Ensure the field exists to prevent errors. Note: A more
efficient option is to test the field's existence in the cfelseif
--->
<cfparam name="FORM.delete_itemID" default="">
<cfloop from="#ArrayLen(SESSION.cart)#" to="1" index="i" step="-1">
<!--- if this item was marked as "deleted", remove it --->
<cfif listFind(FORM.delete_itemID, SESSION.cart[i].itemID)>
<cfset arrayDeleteAt(SESSION.cart, i)>
</cfif>
</cfloop>
<!--- UPDATE item in cart ---->
<cfelseif structKeyExists(FORM, "update_button")>
<cfloop from="1" to="#ArrayLen(SESSION.cart)#" index="i">
<cfset currentItem = session.cart[i]>
<!--- Note: For safety, verify the field exists first --->
<cfset currentItem.quantity = FORM["quantity_" & currentItem.itemID] >
</cfloop>
</cfif>