Why my code in VB is not working? - vb.net

Question

So the task is:
Write a program that contains a text box, a list box and a command button. Put a label above the text box that tells the user to type a number from 1 to 10 inside the text box. When the user clicks the command button, check the text box for a valid number and issue an error message box if the number isn't inside the expected range or in case of empty input. If the user entered a valid number, assign it to the integer variable n and use a For...Next loop to accumulate the sum of the first n elements of an array declared with the statement Dim numList() as Integer = {2, 4, 10, 5, 6, 8, 9, 3, 2, 4} Display the sum in the list box.
Private Sub bCom_Click(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles bCom.Click
Dim n As Integer = CInt(tNum.Text)
If CDbl(tNum.Text) > 10 Then
MessageBox.Show("Please Enter a Number from 1 to 10")
tNum.Focus()
End If
Dim numList() As Integer = {2, 4, 10, 5, 6, 8, 9, 3, 2, 4}
Dim sum As Integer
For Each n As Integer In numList
sum += n
Next
lOut.Items.Add(sum)
End Sub
End Class

Answer 1

You are using a for each loop instead of a for loop, so you iterate over each element in the array, not just the first n ones.
You should use something like:
For x = 0 To n - 1
sum += numList(x)
Next
Some more problems:
No need to convert the text to double if you already converted it to an integer the line before.
You should use Int32.TryParse in case the user enters something that is not a number.
You just check if the number is greater 10, but not if it is smaller than 1.
If the number is invalid, you display a message to the user, then you just keep going on,
but you should exit your method

Answer 2

As others have stated, you need an indexed For..Loop, not a ForEach loop.
You might also consider moving the "is it a valid number" logic to a separate function.
Public Class Form1
Private Sub btnCompute_Click(sender As System.Object, e As System.EventArgs) Handles btnCompute.Click
'is the number valid?
Dim n As Integer = -1
If IsInputValid(txbInput.Text, n) Then
Dim sum As Integer = 0
'declare an array of numbers
Dim numList() As Integer = {2, 4, 10, 5, 6, 8, 9, 3, 2, 4}
'accumulate the sum of the first N elements of the array
For i As Integer = 0 To n - 1
sum += numList(i)
Next
'refresh the listbox with the sum
lbxOutput.Items.Clear()
lbxOutput.Items.Add(sum.ToString)
Else
MessageBox.Show("Please enter a number between 1 and 10")
End If
End Sub
Private Function IsInputValid(input As String, ByRef validnumber As Integer) As Boolean
'input must be a number between 1 and 10
'if it is valid, assign it to the byref validNumber parameter.
Dim i As Integer = -1
If Integer.TryParse(input, i) Then
If i >= 1 AndAlso i <= 10 Then
validnumber = i
Return True
End If
End If
validnumber = i
Return False
End Function
End Class

Answer 3

If I understand your question correctly, you want to sum the first n digits of the array numList.
If this is the case then you need to change your loop code in this way
For x = 0 To n -1
sum += numList(x)
Next
Use x as the indexer to the numList array, start at the first element of the array (x=0) and stop when the indexer has reached the value of n - 1
With this you could satisfy the requirements exactly how they have been asked.
If you wish you could also show an elegant approach using LinQ without an explict loop
sum = numList.Take(n).Sum()
However, before going fancy, it is better that you remove some obvious errors in your code
if Not Int32.TryParse(tNum.Text, n) Then
MessageBox.Show("Error......")
tNum.Focus()
Return
End If
if n < 1 OrElse n > 10 Then
MessageBox.Show("Error......")
tNum.Focus()
Return
End if
And do not use the old fashioned function like CInt e CDbl that are kept only for compatibility with VB6. Use the newest methods like Int32.TryParse, Convert.ToInt32 etc...