Sort rows in decreasing order until a blank row then continue to next blank row - vba

Question

I want to sort rows in a decreasing order "until hitting every blank row."
I have the following code:
For j = 1 To 15
For i = 1 To 15
Do Until mySheet.Cells(i, 1).Value = 0
If mySheet.Cells(j, 2).Value > mySheet.Cells(i, 2).Value Then
For c = 2 To 5
temp1 = mySheet.Cells(i, c).Value
mySheet.Cells(i, c).Value = mySheet.Cells(j, c).Value
mySheet.Cells(j, c).Value = temp1
Next c
End If
i = i + 1
Loop
Next i
Next j
The If statement swaps the rows in decreasing order by comparing the 2nd number of the row.
What went wrong is the Do Until Loop. I'd like to keep checking/swapping the rows until it hits a blank row, but continue to check/swapping for the rows after a blank row. Check, swap, stop when hitting a blank row, then check the next rows again, swap again, so on and so forth.
EDIT
Here is a what's what I am trying to do:
BEFORE:
Row B C D E
1 63743 734 1848 246
2 86208 900 900 974
3 --------**Empty Row**----------
4 40934 730 5643 5565
5 97734 454 54656 3345
6 73885 347 3728 9934
7 --------**Empty Row**----------
8 34355 998 3884 3299
9 98438 383 43483 4399
10 19874 454 53439 3499
11 --------**Empty Row**----------
AFTER:
Row B C D E
1 86208 900 900 974
2 63743 734 1848 246
3 --------**Empty Row**----------
4 97734 454 54656 3345
5 73885 347 3728 9934
6 40934 730 5643 5565
7 --------**Empty Row**----------
8 98438 383 43483 4399
9 34355 998 3884 3299
10 19874 454 53439 3499
11 --------**Empty Row**----------
My If compares the values in Column B, and sorts rows in a decreasing order. I could not figure out how to make a while loop so to stop sorting when hitting a blank row, but then continue comparing/sorting for the next couple rows after a blank row. Note I would not know how many rows there are before a blank row.
EDIT 2
BEFORE:
Row A B C D E
1 A 63743 734 1848 246
2 B 86208 900 900 974
3 -------------**Empty Row**----------
4 C 40934 730 5643 5565
5 D 97734 454 54656 3345
6 E 73885 347 3728 9934
7 -------------**Empty Row**----------
8 F 34355 998 3884 3299
9 G 98438 383 43483 4399
10 H 19874 454 53439 3499
11 -------------**Empty Row**----------
AFTER:
Row A B C D E
1 B 86208 900 900 974
2 A 63743 734 1848 246
3 -------------**Empty Row**----------
4 D 97734 454 54656 3345
5 E 73885 347 3728 9934
6 C 40934 730 5643 5565
7 -------------**Empty Row**----------
8 G 98438 383 43483 4399
9 F 34355 998 3884 3299
10 H 19874 454 53439 3499
11 -------------**Empty Row**----------

Answer 1

The code as it stands can never terminate, because the variable you are checking,
Do Until mySheet.Cells(i, 1).Value = 0
if not changed in any of what follows:
If mySheet.Cells(j, 2).Value > mySheet.Cells(i, 2).Value Then
For c = 2 To 5
temp1 = mySheet.Cells(i, c).Value
mySheet.Cells(i, c).Value = mySheet.Cells(j, c).Value
mySheet.Cells(j, c).Value = temp1
Next c
End If
You loop your c from 2 to 5, so Cells(i,1) is never touched.
This is so fundamental that it's a little bit hard to understand what you were really trying to do, but I'll have a shot at it.
It seems that you want each of columns 2 to 5 (maybe 1 to 5) to be sorted with a bubble sort - check two adjacent cells, move the smaller one to the top, keep going to the bottom of the column. You don't state whether each column has the same length, so I am going to assume it doesn't.
We should be able to sort one column at a time as follows (this is not the most efficient algorithm but it's true to your intention, I think):
Sub sortMyColumns()
Dim colNum As Integer
Dim numRows As Integer
Dim i, j As Integer
Dim lastCell As Range
For colNum = 1 To 5
Set lastCell = Cells(1, colNum).End(xlDown)
numRows = lastCell.Row
For i = 2 To numRows
For j = numRows To i Step -1
If Cells(j, colNum) < Cells(j - 1, colNum) Then
temp = Cells(j - 1, colNum).Value
Cells(j - 1, colNum).Value = Cells(j, colNum).Value
Cells(j, colNum).Value = temp
End If
Next j
Next i
Next colNum
End Sub
For each column, this finds the number of rows; it then starts at the bottom, and pushes the smaller number all the way to the top. It returns to the bottom, but this time only pushes up to one from the top. It continues until it gets to the last two cells - everything should now be sorted.
You may need to add some error trapping in case cells do not contain numerical values etc, but in principle this should work.
EDIT
Based on your comment, this was not what you were looking for. I have created a second Sub which sorts columns B through E based just on the value in B - this mirrors your code example a little better, and may be what you had in mind. I am using the length of column B to find out how many rows to sort - I still don't understand clearly what your column A is doing and how testing it helps you.
If this is still not what you want, I suggest you edit your question with a simple example (screen shot) of the type "this is what my sheet starts out with", and "this is what it has to look like". Just four or five lines of the spreadsheet, and columns A through E, should be sufficient.
Sub sortByColumnB()
' sort cells in columns B through E
' based on the value found in B
Dim colNum As Integer
Dim numRows As Integer
Dim i, j As Integer
Dim lastCell As Range
' find the last cell in column B:
Set lastCell = Cells(1, 2).End(xlDown)
numRows = lastCell.Row
For i = 2 To numRows
For j = numRows To i Step -1
If Cells(j, 2) < Cells(j - 1, 2) Then
' swap around each of the cells in this row with the one above
For colNum = 2 To 5
temp = Cells(j - 1, colNum).Value
Cells(j - 1, colNum).Value = Cells(j, colNum).Value
Cells(j, colNum).Value = temp
Next colNum
End If
Next j
Next i
End Sub
I ran this code on the following dummy spreadsheet:
And it resulted in the following output:
As you can see, column A was untouched, and each row in columns B through E is sorted according to the key in column B. You know of course that there is a built in sort function in Excel, but I assume you had reasons for not wanting to use it...
I hope this is what you needed! If it isn't, then please update your question with and example of "I want THIS to turn into THAT".
EDIT 3
Your latest update to the question plus the comment to my solution finally makes it clear what you intend to do. Since we can't really know we have reached the last block until we "fall off the edge", I have modified the code so it has an infinite loop with an error trap (that is generated when you try to go beyond the bottom of the spreadsheet). I tested this with blank row all the way (including blank in column A - note the code no longer uses column A at all):
Sub keepSorting()
Dim colNum As Integer
Dim firstRow, lastRow As Integer
Dim i, j As Integer
' loop around the algorithm we had earlier, but only for the 'non-empty blocks of rows'
firstRow = 1
lastRow = [B1].End(xlDown).Row
On Error GoTo allDone
While True ' break out of the loop when we throw error
' sort from firstRow to lastRow:
For i = firstRow + 1 To lastRow
For j = lastRow To i Step -1
If Cells(j, 2) > Cells(j - 1, 2) Then
' swap around each of the cells in this row with the one above
For colNum = 1 To 5
temp = Cells(j - 1, colNum).Value
Cells(j - 1, colNum).Value = Cells(j, colNum).Value
Cells(j, colNum).Value = temp
Next colNum
End If
Next j
Next i
firstRow = Cells(lastRow + 1, 2).End(xlDown).Row
lastRow = Cells(firstRow, 2).End(xlDown).Row
Wend
allDone:
On Error GoTo 0
End Sub
It turns THIS:
into THIS:
Note - the On Error Resume Next is there because finding the lastRow when firstRow is at the bottom of the sheet generates an error; but since we're done by that time, we just need to exit the while loop...

Answer 2

There are a lot of ways to do this, but if you want to keep your nested For approach the first thing you need to do is find out how many rows there are before you hit a blank.
Dim lngTotalRows As Long
lngTotalRows = 0
While Cells(lngTotalRows + 1, 1) <> ""
lngTotalRows = lngTotalRows + 1
Wend
Now that you have that, you can just basically use your existing code replacing your 15 with lngTotalRows. You do have a couple small problems with your loops though...
Your outer loop should be:
For j = 1 to lngTotalRows - 1
Your inner loop should be:
For i = j + 1 to lngTotalRows
If you look at a couple specific example you will probably see why. You are comparing your outer loop cell to each cell after it, so the first time through the loop our first cell will have j = 1 (so the cell in Row 1) and we are comparing it to every row after that, so we start at j + 1 (which is Row 2), then we look at row 3, row 4 and so on. When the outer loop is looking at Row 10 the inner loop will just look at the values between Row 11 and the end of the sort range.
The outer loop ends at lngTotalRows - 1 because the inner loop will be looking at the cell after that one which will be the last cell in the range.
See if you can implement that in your existing code. If things aren't behaving as you expect use breakpoints and inspect the values while you step through the code. It can be very enlightening. Also you can use Debug.Print statements in your code to output values to the immediate window to help track down problems.