MS Access Looping a union query through all columns? - sql

Question

Is it possible to simplify the following into a loop?
SELECT ID as ColHead, "Field1" AS RowHead, Field1 AS TheVal
FROM `master`
UNION
SELECT ID, "Field2",Field2
FROM `master`
UNION
SELECT ID, "Field3",Field3
FROM `master`
UNION
...
SELECT ID, "Field90",Field90
FROM `master`
There are 90 fields. Before I start writing this by hand, is there a way to simplify the process?

Answer 1

If you build that massive UNION query, consider UNION ALL instead.
UNION ALL will return all rows from each SELECT piece, including duplicate rows. With just UNION, the db engine returns only distinct rows. However ensuring distinct rows imposes a greater burden on the engine.
Use UNION if you require only distinct rows. Use UNION ALL if you can accept duplicate rows. Also use UNION ALL when the candidate rows can not include duplicates to begin with.
If that ID field is the master primary key, or if you have another unique constraint (index) on ID, the candidate rows will already be unique. If that is your situation, use UNION ALL to make that big query easier on the db engine.
Actually I'm apprehensive about trying to UNION (or UNION ALL) 89 SELECTs. I've never attempted such a huge SQL statement. If you want to try, I'll offer another approach.
I created a VBA function to create the SQL statement. It reads the field names from the TableDef and loops through those names to add a SELECT piece for each field name.
Here is an Immediate window session where I tested the function in Access 2007. My master table includes only 4 fields: ID; fld1; fld2; and fld3.
? BuildUnionStatement
SELECT ID as ColHead, 'fld1' AS RowHead, [fld1] AS TheVal
FROM [master]
UNION ALL
SELECT ID as ColHead, 'fld2' AS RowHead, [fld2] AS TheVal
FROM [master]
UNION ALL
SELECT ID as ColHead, 'fld3' AS RowHead, [fld3] AS TheVal
FROM [master]
I don't know what you intend to do with the query after you create it. But a function to create the SQL offers flexibility. You could use the function's output to open a recordset, save it as a QueryDef, for the record source of a form or report, etc.
Public Function BuildUnionStatement() As String
Const cstrTable As String = "master"
Dim db As DAO.database
Dim fld As DAO.Field
Dim tdf As DAO.TableDef
Dim strPattern As String
Dim strSql As String
'strPattern = vbCrLf & "UNION" & vbCrLf &
strPattern = vbCrLf & "UNION ALL" & vbCrLf & _
"SELECT ID as ColHead, " & _
"'FLDNAME' AS RowHead, " & _
"[FLDNAME] AS TheVal" & vbCrLf & _
"FROM [" & cstrTable & "]"
Set db = CurrentDb
Set tdf = db.TableDefs(cstrTable)
For Each fld In tdf.Fields
If fld.Name <> "ID" Then
strSql = strSql & Replace(strPattern, _
"FLDNAME", fld.Name)
End If
Next
Set fld = Nothing
Set tdf = Nothing
Set db = Nothing
'BuildUnionStatement = Mid(strSql, 10) ' UNION
BuildUnionStatement = Mid(strSql, 14) ' UNION ALL
End Function
After you save that function in a module, open the Immediate window (Ctrl+g). To execute the function, type this and press Enter
? BuildUnionStatement
Copy the text it returns, create a new query and switch to SQL View, then paste in the copied text.
Since that gave you too much text to copy from the Immediate window, create a new query --- any query will work. Then assign the function's output to the query's SQL property. Do this in the Immediate window ...
CurrentDb.QueryDefs("YourQueryNameHere").SQL = BuildUnionStatement