Mathematica - Solve equation as an expression of two variables - variables

Question

Simple question, all I want to do is have Solve[] work in a way that instead of solving for a single variable (eg. Vo) it solves for the expression Vo/Vi. In all cases this just equates to dividing both sides by Vi, as it'll cancel out on the RHS anyway, curious if there's a quick way to do it though.
Thanks
EDIT: Here's the code
vd = 0 - V1;
VL = Solve[(V1 - Vi)/R1 + (V1 - Vo)/R2 == 0, V1][[All, 1, 2]][[1]];
VR = Solve[(Vo - V1)/R2 + (Vo - (AO*vd))/RO == 0, V1][[All, 1, 2]][[1]];
Av = Solve[VL == VR, Vo][[All, 1, 2]][[1]];
Av = Av/Vi //I add this to remove the Vi
Basically I want it to solve for Vo/Vi, to automatically remove the Vi from the RHS...

Answer 1

You seem to be using V1 as a placeholder in Solve to get VL and VR. Let's get rid of V1 by putting VL and VR directly into those equations. This means that we also need to define vd as 0 - VR.
Also, let's define Av as Vo/Vi.
We can stuff all of the equations into Eliminate, asking it to eliminate Vo, Vi, VL, VR, and vd:
In[72]:= Eliminate[
vd == 0 - VR
&& (VL - Vi)/R1 + (VL - Vo)/R2 == 0
&& (Vo - VR)/R2 + (Vo - (AO*vd))/RO == 0
&& VL == VR
&& Av == Vo/Vi,
{Vo, Vi, vd, VL, VR}]
Out[72]= Av (1 + AO + R2/R1 + RO/R1) == (-AO R2 + RO)/R1 && R1 != 0 &&
R2 != 0 && RO != 0
That's pretty close to what we want, but it's not quite solved for Av, so let's do that too:
In[73]:= Solve[
Eliminate[
vd == 0 - VR
&& (VL - Vi)/R1 + (VL - Vo)/R2 == 0
&& (Vo - VR)/R2 + (Vo - (AO*vd))/RO == 0
&& VL == VR
&& Av == Vo/Vi,
{Vo, Vi, vd, VL, VR}],
Av]
Out[73]= {{Av -> (-AO R2 + RO)/(R1 + AO R1 + R2 + RO)}}
If you want to actually define the symbol Av, we can do that using /. (ReplaceAll):
In[80]:= Av =.; Av = Av /. Solve[
Eliminate[
vd == 0 - VR
&& (VL - Vi)/R1 + (VL - Vo)/R2 == 0
&& (Vo - VR)/R2 + (Vo - (AO*vd))/RO == 0
&& VL == VR
&& Av == Vo/Vi,
{Vo, Vi, vd, VL, VR}],
Av][[1]];
In[81]:= Av
Out[81]= (-AO R2 + RO)/(R1 + AO R1 + R2 + RO)