Transfer data from one listview to another when data been double click - vb.net

Question

I have 2 ListView setup.
Listview1 need to pass the data to listview2 when any of the data is double click by user.
How can I archive this? I am using vb 2008.
here is the image :

Answer 1

This is crude and simple, but it will give you a starting point. Note that there are any number of ways to approach this problem, and you will want to figure out any validation and such as required by your application. The biggest hurdle appears to be grabbing a reference to the item which is the target of the double click (as important, making sure that if the user double-clicks in an empty area of the ListView Control, that the last selected item is not added by mistake.
Hope this helps:
Public Class Form1
Private Sub Form1_Load(sender As System.Object, e As System.EventArgs) Handles MyBase.Load
Me.ListView1.FullRowSelect = True
Me.ListView2.FullRowSelect = True
End Sub
Private Sub AddItemToSecondList(ByVal item As ListViewItem)
' NOTE: We separate this part into its own method so that
' items can be added to the second list by other means
' (such as an "Add to Purchase" button)
' ALSO NOTE: Depending on your requirements, you may want to
' add a check in your code here or elsewhere to prevent
' adding an item more than once.
Me.ListView2.Items.Add(item.Clone())
End Sub
Private Sub ListView1_MouseDoubleClick(sender As Object, e As System.Windows.Forms.MouseEventArgs) Handles ListView1.MouseDoubleClick
' Use the HitTest method to grab a reference to the item which was
' double-clicked. Note that if the user double-clicks in an empty
' area of the list, the HitTestInfo.Item will be Nothing (which is what
' what we would want to happen):
Dim info As ListViewHitTestInfo = Me.ListView1.HitTest(e.X, e.Y)
'Get a reference to the item:
Dim item As ListViewItem = info.Item
' Make sure an item was the trget of the double-click:
If Not item Is Nothing Then
Me.AddItemToSecondList(item)
End If
End Sub
End Class