How can I programmatically remove text from a ReadOnly RichTextBox? - vb.net

Question

The following code aims to maintain a text buffer in a ReadOnly RichTextBox, with a maximum number of characters stored, and always kept scrolled to the bottom. It streams a realtime log.
But in my attempt to maintain the maximum character count, rtMessages.TextLength() isn't changing after rtMessages.SelectedText = String.Empty and consequently, without the defensive If block, I'd end up with an infinite loop attempting to repeatedly delete the first line of the buffer.
When I remove the ReadOnly-ness of the RichTextBox, this functionality succeeds. Seems a little strange, since AppendText succeeds, but I understand that selection is a different beast.
Can I make it so that a ReadOnly RichTextBox is programmatically modifiable?
Private Sub onNewData(ByRef data As String) Handles _server.clientSentData
' Add new text
rtMessages.SelectionStart = rtMessages.TextLength()
rtMessages.AppendText(data)
' Delete oldest text line-by-line until the whole buffer is shorter than MAX_TEXT_LENGTH characters
Const MAX_TEXT_LENGTH = 200
Dim textLength = rtMessages.TextLength()
While textLength > MAX_TEXT_LENGTH
Dim i As Int16 = 0
Do While rtMessages.GetLineFromCharIndex(i) < 1
i += 1
Loop
rtMessages.Select()
rtMessages.SelectionStart = 0
rtMessages.SelectionLength = i
rtMessages.SelectedText = String.Empty
rtMessages.SelectionLength = 0
If rtMessages.TextLength() = textLength Then
rtMessages.Clear()
rtMessages.AppendText("[buffer trimming algorithm failed]")
Exit While
End If
textLength = rtMessages.TextLength()
End While
' Scroll down
rtMessages.SelectionStart = rtMessages.TextLength()
rtMessages.ScrollToCaret()
End Sub

Answer 1

While trying to replace SelectedText in a ReadOnly RichTextBox doesn't work, using the SelectedRtf does work:
'rtMessages.Select()
'rtMessages.SelectionStart = 0
'rtMessages.SelectionLength = i
'rtMessages.SelectedText = String.Empty
'rtMessages.SelectionLength = 0
rtMessages.Select(0, i)
rtMessages.SelectedRtf = "{\rtf1\ansi}"

Answer 2

rtMessages.SelectionLength = i - 1
Should be replaced by
rtMessages.SelectionLength = i
EDIT #1
By adding the -1 to the SelectionLength, you're missing the last character of the first line. On the second run, only 1 character will be on the first line (the one you missed on the first run). Then you will try to delete a SelectionLength of 0 and you'll get the same TextLength for every other runs and there you go with the infinite loop!

Answer 3

You can remove the read-only parameter, write your appendtext code and then make the richtextbox readonly again.

Answer 4

I know this is an old thread, but you can get around the ReadOnly issue the replacing the following code:
rtMessages.Select()
rtMessages.SelectionStart = 0
rtMessages.SelectionLength = i
rtMessages.SelectedText = String.Empty
rtMessages.SelectionLength = 0
with this:
rtMessages.Text = rtMessages.Text.Substring(i)
I'm not sure if this is better or worse performance, but it gets around the RichTextBox being set as ReadOnly
Edit:
Here is the complete code used to test this (Note: I added the code to a Button.Click for testing)
Private Sub Button1_Click(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles Button1.Click
Static X As Integer = 0
X += 1
Dim Data As String = "Line " & X.ToString & ControlChars.NewLine
Me.onNewData(Data)
End Sub
Private Sub onNewData(ByRef data As String)
' Add new text
rtMessages.SelectionStart = rtMessages.TextLength()
rtMessages.AppendText(data)
' Delete oldest text line-by-line until the whole buffer is shorter than MAX_TEXT_LENGTH characters
Const MAX_TEXT_LENGTH As Integer = 200
Dim textLength As Integer = rtMessages.TextLength()
While textLength > MAX_TEXT_LENGTH
Dim i As Integer = 0
Do While rtMessages.GetLineFromCharIndex(i) < 1
i += 1
Loop
'rtMessages.Select()
'rtMessages.SelectionStart = 0
'rtMessages.SelectionLength = i
'rtMessages.SelectedText = String.Empty
'rtMessages.SelectionLength = 0
rtMessages.Text = rtMessages.Text.Substring(i)
If rtMessages.TextLength() = textLength Then
rtMessages.Clear()
rtMessages.AppendText("[buffer trimming algorithm failed]")
Exit While
End If
textLength = rtMessages.TextLength()
End While
' Scroll down
rtMessages.SelectionStart = rtMessages.TextLength()
rtMessages.ScrollToCaret()
End Sub