how to encrypt and decrpyt files with adobe air ? (encrypt ok, but decrpyt isn't yet ) - air

Question

i want to encrypt and decrpyt files with adobe air. and i am successfully encrypt files with code. but i dont yet decrpyt an encrypted file please help me, what can i do?
i am using this code for encrypt:
import com.hurlant.crypto.symmetric.AESKey;
import com.hurlant.crypto.symmetric.DESKey;
import com.hurlant.util.Hex;
import flash.filesystem.FileStream;
import flash.filesystem.File;
import flash.utils.ByteArray;
import flash.filesystem.FileMode;
import flash.display.BitmapData;
import flash.display.Bitmap;
import com.hurlant.util.ArrayUtil;
stop();
var stream:FileStream;
var stream2:FileStream;
var file:File;
var fileToEncrypt:ByteArray;
encrypt();
function encrypt():void
{
file = File.applicationDirectory.resolvePath("logo_markatalog.png");
fileToEncrypt = new ByteArray;
stream = new FileStream();
stream.open( file, FileMode.READ );
stream.readBytes(fileToEncrypt);
stream.close();
var appDir:String = File.applicationDirectory.nativePath;
//file = File(appDir+"logo_markatalog_enc.png");
file = new File(appDir+"/logo_markatalog_enc.png");
var key:ByteArray = Hex.toArray("635232557");
var aes:AESKey = new AESKey(key);
aes.encrypt(fileToEncrypt);
stream2 = new FileStream();
stream2.open( file, FileMode.WRITE );
stream2.writeBytes(fileToEncrypt);
stream2.close();
}

Answer 1

I can't tell you what you're doing wrong but I can give you what I use to encrypt object into file and decrypt them back.
someKey var is your key used to encrypt and decrypt.
theFileWithEncryptedObject var is the file where I save my encrypted object in the first code part, from which I read the encrypted object in second code part.
I use an md5 hash on the key, that's not necessary.
Here's the way I encrypt object into file with hurlant.crypto :
var fileStream:FileStream = new FileStream();
fileStream.open(theFileWithEncryptedObject, FileMode.WRITE);
var bytes:ByteArray = new ByteArray();
bytes.writeObject(theObjectToEncrypt);
var key:ByteArray = Hex.toArray(someKey);
var md5:MD5 = new MD5();
key = md5.hash(key);
var pad:IPad = new PKCS5();
var aes:ICipher = Crypto.getCipher("simple-aes-128-cbc", key, pad);
pad.setBlockSize(aes.getBlockSize());
aes.encrypt(bytes);
fileStream.writeBytes(bytes);
fileStream.close();
And here how I decrypt and get back my object from the file :
var bytes:ByteArray = new ByteArray();
var fileStream:FileStream = new FileStream();
fileStream.open(theFileWithEncryptedObject, FileMode.READ);
fileStream.readBytes(bytes);
fileStream.close();
var key:ByteArray = Hex.toArray(someKey);
var md5:MD5 = new MD5();
key = md5.hash(key);
var pad:IPad = new PKCS5;
var aes:ICipher = Crypto.getCipher("simple-aes-128-cbc", key, pad);
pad.setBlockSize(aes.getBlockSize());
aes.decrypt(bytes);
var theObjectDecrypted:Object;
bytes.position = 0;
theObjectDecrypted = bytes.readObject();
Hope this helps.