Writing formula into Excel through Access VBA - vba

Question

I want to insert in "A1" some text "ABC" and the following cell in "B1" an if statement. However I get only the first entry "ABC" inserted and then an error at FormulaR1C2 "Object doesn't support this property or method". I'm not sure I'm using the R1C2 correctly. I was assuming it stood for Row 1 Column 2, can someone help me out.
Dim Excel_App As Object
Dim strExcel As String
Set Excel_App = CreateObject("Excel.Application")
Excel_App.Visible = True
Excel_App.Workbooks.Add
With Excel_App
.Range("A:B").EntireRow.ColumnWidth = 25
.Range("A2").EntireRow.Font.FontStyle = "Bold"
.ActiveCell.FormulaR1C1 = "ABC"
strExcel = "=IF(A1 = """"," & """EMPTY""" & "," & """FILLED""" & ") "
.ActiveCell.FormulaR1C2 = strExcel
End With

Answer 1

FormulaR1C1 is the method of how the formula is written.
Formula refers to writing a formula in A1 like =B1+C1.
To write that same formula using R1C1 notation, you would write =RC[1] + RC[2]. Furthermore to write =B2+C2 in A1 write this =R[1]C[1] + R[1]C[2] -> so you can see you are offsetting the columns and rows where you want the formula to return values from.
What you want to do in your code is offset the place where the formula will be placed, rather than how it's calculating, so you should write this:
.ActiveCell.Offset(,1).Formula = strExcel
Actually, you should get rid of ActiveCell altogether, unless you absolutely need it.
I would write your code like this for better, more accurate execution:
Dim Excel_App As Object
Dim strExcel As String
Dim wkb as Object, wks as Object
Set Excel_App = CreateObject("Excel.Application")
Excel_App.Visible = True
Set wkb = Excel_App.Workbooks.Add
Set wks = wkb.Sheets(1) 'assumes you want first sheet, can modify for sheet index or name
With wks
.Range("A:B").EntireRow.ColumnWidth = 25
'I think this will actually set every row to 25, is that what you want?
.Range("A2").EntireRow.Font.FontStyle = "Bold"
.Range("A1").Value = "ABC" 'don't need to write Value, but just to show you the property
strExcel = "=IF(A1 = """"," & """EMPTY""" & "," & """FILLED""" & ") "
.Range("B1").Formula = strExcel
End With

Answer 2

FormulaR1C1 is a property which returns the formula of a cell expressed in R1C1 formula style.
You need to reference cells by using the Workbook.WorkSheet.Range syntax.
So first you need to specify the workbook you are working in, which in your case is the workbook added by the statement Excel_App.Workbooks.Add. Your new workbook is automatically named something like "Book1" and automatically has the default number of worksheets added named "Sheet1" through "Sheetn" where n is the default number of sheets.
So you're final code to write to that line is
Excel_App.Workbooks(1).Worksheets("Sheet1").Cells(1, 1) = "ABC"
Excel_App.Workbooks(1).Worksheets("Sheet1").Cells(1, 2).Formula = "=IF(A1 = """"," & """EMPTY""" & "," & """FILLED""" & ")"