VbScript/ASP Classic good OOP Pattern [closed] - oop

Question

It's difficult to tell what is being asked here. This question is ambiguous, vague, incomplete, overly broad, or rhetorical and cannot be reasonably answered in its current form. For help clarifying this question so that it can be reopened, visit the help center.
Closed 10 years ago.
Hy all,
I have to create a website in Classic ASP, and i really want to do a clean design so i will try to put everything in Classes and Models to emulate the ViewModel Pattern.
So can you tell me if this approch of creating objects is good because i will use it everywhere
Class User
Public Name
Public Adress
Public Title
Public Text
Public Rights 'ArrayList of Right objects
Private Sub Class_Initialize()
Initialize
End Sub
Private Sub Class_Terminate()
Dispose
End Sub
Private Sub Initialize()
Name = ""
Adress = ""
Title = ""
Text = ""
Set Rights = Server.CreateObject("System.Collections.ArrayList") ' Arraylist .net
End Sub
Private Sub Dispose()
End Sub
End Class
Class Right
Public Name
Private Sub Class_Initialize()
Initialize
End Sub
Private Sub Class_Terminate()
Dispose
End Sub
Private Sub Initialize()
Name = ""
End Sub
Private Sub Dispose()
End Sub
End Class
And then i do this for instantiating objects :
Dim myUser
Set myUser = New User
'Do some work
Set myUser = nothing 'Dispose the object
Any idea, suggestion or correction is welcome.
Thanks for help.

Answer 1

VBScript does not support object instantiation with parameters, but you could add it like this:
Public Function [New User](name)
Set [New User] = New User
[New User].Name = name
End Function
Now you can create a user like:
Set myUser = [New User]("Arthur Dent")
Usefull when you have mandatory fields you want to set during initialization.
You can also make composites with this technique:
Public Function [New PowerUser](name)
Set [New PowerUser] = New User
[New PowerUser].Name = name
Set [New PowerUser].Rights = RightsCollection("PowerUser")
End Function
Public Function [New GuestUser](name)
Set [New GuestUser] = New User
[New GuestUser].Name = name
Set [New GuestUser].Rights = RightsCollection("Guest")
End Function

Answer 2

it don't see a need to create an extra function "Initialize" and "Dispose" and call that from within Class_Initialize() and Class_Terminate() respectively.
You can just put the code inside the class constructor and destructor.
Secondly, you made your members variables public, if you'd like to make your classic asp work as much object-oriented as possible you should start using getters and setters.
Thus like this:
Private m_Name
Public Property Get Name()
Name = m_Name
End Property
Public Property Let Name(sName)
m_Name = sName
End Property
With the Rights member variable you're going have more fun :)