VBS Script - Do Until (Success = True or Fail = True) - scripting

Question

I am trying to uninstall a ClickOnce application programmatically using a VBS script. It works pretty well. But if the uninstall fails I want it to send a response "Application has already been removed".
The below is what I have so far, and it works for the most part. Sometimes the delay is not long enough or another window steals focus and the "OK" for sendkeys does not make it to the window.
--- Full Source Code ---
On Error Resume Next
Set objShell = WScript.CreateObject("WScript.Shell")
objShell.Run "taskkill /f /im TEST.App.UI.exe*"
objShell.Run "rundll32.exe dfshim.dll,ShArpMaintain test.app.ui.application, Culture=neutral, PublicKeyToken=f77d770cef, processorArchitecture=msil"
Do Until Success = True
Success = objShell.AppActivate("Test App")
Wscript.Sleep 500
Loop
objShell.SendKeys "OK"
'Commented out on purpose
'install new
'objShell.Run ""

Answer 1

When tackling problems of logical control flow, it's best to start with a
story/description:
I want to start an uninstall process and wait for it to terminate with
either success or failure (indicated by opening a window with
appropriate title)
Never use comparison against True/False in conditions; that's just error-prone
fat.
Don't rely on VBscript's intelligence to convert non-booleans; use
variables/expressions of appropriate (sub) type in conditionals.
Remember that VBScript doesn't shortcut the evaluation of conditionals:
If This() Or That() Then
will call both functions, even if This returns True (and therefore the
whole clause must be True). So don't be tempted to do:
... Until (objShell.AppActivate("Uninstall - Success") Or _
objShell.AppActivate("Uninstall - Failure"))
When designing a loop, think about when the leave-checking should be done; if
you want to read from a possibly empty file, it makes sense to check early:
Do Until tsIn.AtEndOfStream
sLine = tsIn.ReadLine()
...
Loop
but if you want to get valid input from the user, you have to ask before
you can check:
Do
sInp = ...
Loop While isBad(sInp)
.AppActivate and .SendKeys are every programmer's foes; postpone fighting
against them, until you have the control flow problem solved.
In code:
' Wait Wait Fail Success
' , Array(False, False, True , True ) _ shouldn't happen, but will terminate too
Dim aHappenings : aHappenings = Array( _
Array(False, False, False, True ) _
, Array(False, False, True , False) _
)
Dim aTest
For Each aTest In aHappenings
WScript.Echo Join(aTest)
Dim bOk : bOk = False
Dim bFail : bFail = False
Dim i : i = 0
Do
bOk = aTest(i + 0)
bFail = aTest(i + 1)
WScript.Echo Join(Array(" ", i, bOk, bFail))
i = i + 2
Loop Until bOk Or bFail
WScript.Echo "Done."
WScript.Echo
Next
Output:
False False False True
0 False False
2 False True
Done
False False True False
0 False False
2 True False
Done.
You may exploit the fact, that either success or failure (not both) will happen:
Dim i : i = 0
Dim bDone
Do
bDone = aTest(i + 0)
If Not bDone Then
bDone = aTest(i + 1)
End If
WScript.Echo Join(Array(" ", i, bDone))
i = i + 2
Loop Until bDone