Search listbox for string, DataSource property set - vb.net

Question

I'm trying to make TextBox1 a search bar, to search for specific strings in ListBox1.
I want it to remove other items that don't have the string I searched. The list shows all files in a specific directory, so if I search "icon_" it would only show files with icon_ in the name. Is this possible?
I've asked this question a while ago, but I can't use any of the answers because the listbox is being populated by filenames from a specific directory, which gives me this error:
Items collection cannot be modified when the DataSource property is set.

Answer 1

Lots of different ways to do this.
This method puts your list of files into a DataTable and using a BindingSource, you can use it's Filter property to filter the list.
Here is a form with a ListBox and a TextBox:
Public Class Form1
Dim bs As New BindingSource
Public Sub New()
InitializeComponent()
End Sub
Protected Overrides Sub OnLoad(ByVal e As System.EventArgs)
MyBase.OnLoad(e)
Dim testPath As String = "c:\MyPath"
Dim dt As New DataTable
dt.Columns.Add("File", GetType(String))
For Each f As String In Directory.GetFiles(testPath)
Dim row As DataRow = dt.NewRow
row("File") = Path.GetFileName(f)
dt.Rows.Add(row)
Next
bs.DataSource = dt
ListBox1.DisplayMember = "File"
ListBox1.ValueMember = "File"
ListBox1.DataSource = bs
End Sub
Private Sub TextBox1_TextChanged(ByVal sender As Object, ByVal e As EventArgs) Handles TextBox1.TextChanged
bs.Filter = String.Format("File LIKE '*{0}*'", TextBox1.Text)
End Sub
End Class

Answer 2

When the DataSource property is set, you cannot modify the list. While it is convenient to populate a ListBox control using the DataSource property, it is certainly not necessary. You can add the items to the control using its Items.Add method, instead. For instance, borrowing from my answer to your previous question:
Public Class FileSearchTool
Public Sub New(ByVal listBox As ListBox, ByVal textBox As TextBox)
_listBox = listBox
_textBox = textBox
End Sub
Private _listBox As ListBox
Private WithEvents _textBox As TextBox
Private _fileNames As New List(Of String)()
Private _folderPath As String
Public Property FolderPath() As String
Get
Return _folderPath
End Get
Set(ByVal value As String)
_folderPath = value
loadFilePaths()
End Set
End Property
Private Sub loadFilePaths()
_fileNames = New List(Of String)(Directory.GetFiles(_folderPath))
refreshList()
End Sub
Private Sub _textBox_TextChanged(ByVal sender As Object, ByVal e As EventArgs) Handles _textBox.TextChanged
refreshList()
End Sub
Private Sub refreshList()
_listBox.SuspendLayout()
_listBox.Items.Clear()
For Each item As String In _fileNames
If item.StartsWith(_textBox.Text, StringComparison.CurrentCultureIgnoreCase) Then
_listBox.Items.Add(item)
End If
Next
_listBox.ResumeLayout()
End Sub
End Class
Then in any form you could use it like this:
Public Class Form1
Private _tool As FileSearchTool
Private Sub Form1_Load(ByVal sender As Object, ByVal e As EventArgs) Handles MyBase.Load
_tool = New FileSearchTool(ListBox1, TextBox1)
_tool.FolderPath = "C:\"
End Sub
End Class
But, at that point, you might as well just encapsulate it further by creating a FileSearch user control.
Or, As I said in my answer to your previous question, if all you want is an auto complete box, you can just use a text box without a listbox at all as such:
Dim source As New AutoCompleteStringCollection()
source.AddRange(Directory.GetFiles("C:\"))
TextBox1.AutoCompleteCustomSource = source
TextBox1.AutoCompleteMode = AutoCompleteMode.Suggest
TextBox1.AutoCompleteSource = AutoCompleteSource.CustomSource
In fact, another interesting option is that you can set AutoCompleteSource to FileSystem, which you may want to play with.