Run rules on the Sent Items folder - vba

Question

I have rules in Outlook for incoming and posted emails.
I found in the web the following routine which works for the emails which are in the 'INBOX'.
I am not able to use the GetRootFolder to select the 'Sent Items' folder.
The routine is the following:
Sub RunRules()
Dim st As Outlook.Store
Dim myRules As Outlook.rules
Dim rl As Outlook.Rule
Dim count As Integer
Dim k As Long
Dim fname As String
Dim currentcount As Integer
Dim prova As String
Dim numero As Integer
Dim prova1 As String
Dim Nrules As Integer
Dim objFolder, objNamespace, objOutlook, objFile
Set objOutlook = CreateObject("Outlook.Application")
Set objNamespace = objOutlook.GetNamespace("MAPI")
objNamespace.Logon "Default Outlook Profile", , False, False
numero = 1
' this is for the SENT Items
fname = "I"
count = 1
k = 1
Set rl = Nothing
Set st = Nothing
Set myRules = Nothing
'On Error Resume Next
' get default store (where rules live)
Set st = Application.Session.DefaultStore
Application.Session.DefaultStore.GetRootFolder (olFolderSentMail)
' get rules
Set myRules = st.GetRules
For k = 1 To myRules.count ' might be 0-based, didnt check
On Error Resume Next
Set rl = Nothing
Set rl = myRules(k)
If rl.RuleType = olRuleReceive Then 'determine if it’s an Inbox rule, if so, run it
' I selecto just the rules that are for the sent ITEMS
prova = rl.Name
prova1 = Left(prova, 1)
If prova1 = fname Then
rl.Execute ShowProgress:=True
objFile.WriteLine rl.Name
count = count + 1
prova = ""
prova1 = ""
End If
End If
Next
Set rl(count) = Nothing
Set st = Nothing
Set myRules = Nothing
Set objFolder = Nothing
End Sub

Answer 1

Sorry, I did not notice your question before.
I have not tried your code. Instead I show an extract from one of my routines which moves selected properties to variables from every mail item in the Sent Items folders.
Hope this helps.
Dim FolderTgt As MAPIFolder
Dim HtmlBody As String
Dim InxItemCrnt As Long
Dim ReceivedTime As Date
Dim SenderEmailAddress As String
Dim SenderName As String
Dim Subject As String
Dim TextBody As String
Dim FolderTgt As MAPIFolder
Set FolderTgt = CreateObject("Outlook.Application"). _
GetNamespace("MAPI").GetDefaultFolder(olFolderSentMail)
For InxItemCrnt = FolderTgt.Items.Count To 1 Step -1
With FolderTgt.Items.Item(InxItemCrnt)
If .Class = olMail Then
' Save selected data to variables
ReceivedTime = .ReceivedTime
Subject = .Subject
SenderName = .SenderName
SenderEmailAddress = .SenderEmailAddress
TextBody = .Body
HtmlBody = .HtmlBody
End If
End With
Next

Answer 2

Unless specified, rules run on the Inbox of the default store, regardless of the store with the rules.
Option Explicit
Sub RunRules()
Dim st As Store
Dim myRules As rules
Dim rl As Rule
Dim count As Long
Dim k As Long
Dim fname As String
Dim prova As String
Dim prova1 As String
Dim objFolder As Folder
' this is for the SENT Items
fname = "I"
' get store (can be any store)
Set st = Session.defaultStore
' get rules from specified store
Set myRules = st.GetRules()
' The default folder is the Inbox of the default store,
' regardless of the store with the rules.
Set objFolder = st.GetDefaultFolder(olFolderSentMail)
Debug.Print "objFolder: " & objFolder
For k = 1 To myRules.count
Set rl = myRules(k)
Debug.Print rl.RuleType ' 0 = olRuleReceive, 1 = olRuleSend
If rl.RuleType = olRuleSend Then
' rule name starting with "I"
prova = rl.name
prova1 = Left(prova, 1)
If prova1 = fname Then
' Designate a folder if not the Inbox of the default store
rl.Execute ShowProgress:=True, Folder:=objFolder
count = count + 1
End If
End If
Next
Debug.Print count & " rules processed"
End Sub