Force hyperlinks to open target files in notepad - vba

Question

I have a script that goes and grabs all of the documents from a certain folder and lists all of the files in that folder. It then goes and makes a link to open these files from inside of Excel. I was wondering if there was a way to put it in a shell so that the files only opened in notepad. The code that I am using right now is:
Sub MakeLink(ByVal cell As Range, ByVal url As String, ByVal txt As String, ByVal tooltip_text As String)
ActiveSheet.Hyperlinks.Add _
Anchor:=cell, _
Address:=url, _
ScreenTip:=tooltip_text, _
TextToDisplay:=txt
End Sub
Sub Portfolios()
Range("A1:Z200").Clear
Dim objFSO As Object
Dim objFolder As Object
Dim objFile As Object
Dim ws As Worksheet
Range("A3").Font.Bold = True
Set objFSO = CreateObject("Scripting.FileSystemObject")
Set ws = Worksheets("Library")
'Get the folder object associated with the directory
Set objFolder = objFSO.GetFolder("C:\Portfolios")
ws.Cells(3, 1).Value = "The files found in " & objFolder.Name & " are:"
'Loop through the Files collection
For Each objFile In objFolder.Files
'ws.Cells(ws.UsedRange.Rows.Count + 3, 2).Value = objFile.Name
MakeLink ws.Cells(ws.UsedRange.Rows.Count + 3, 2), objFile, objFile.Name, objFile.Name
Next
'Clean up!
Set objFolder = Nothing
Set objFile = Nothing
Set objFSO = Nothing
End Sub
I know I have to do something along the lines of MakeLink = Shell("C:\WINDOWS\notepad.exe", 1) but I seem to be hitting a bit of a snag as to where this will fit.
Thanks,
F

Answer 1

Files will open in whatever is the default program for the file type.
If you want to force them to open in notepad then you'll have to write some code to process the Worksheet_FollowHyperlink event: you can get the cell text from the Target parameter and shell out notepad from there.
To prevent problems with the hyperlink taking users elsewhere, just set the target address to the same cell as the one containing the hyperlink.
Private Sub Worksheet_FollowHyperlink(ByVal Target As Hyperlink)
Dim fPath As String, res
fPath = Target.TextToDisplay
res = Shell("notepad.exe """ & fPath & """", vbNormalFocus)
End Sub
To create the hyperlinks:
Sub MakeLink(rng As Range, txt As String)
Dim addr As String
addr = "'" & rng.Parent.Name & "'!" & rng.Address(False, False)
rng.Parent.Hyperlinks.add Anchor:=rng, Address:="", _
SubAddress:=addr, TextToDisplay:=txt
End Sub