Access child package declarations - packaging

Question

Is it possible to access child package declarations from a parent package ?
-- parent.ads
package Parent is
procedure F(A : Child_Type);
end Parent;
-- parent-child.ads
package Parent.Child is
type Child_Type is (A, B, C);
end Parent.Child;
The nested version works fine :
-- parent.ads
package Parent is
package Child is
type Child_Type is (A, B, C);
end Child;
use Child;
procedure F(A : Child_Type);
end Parent;
And maybe there is another way to do this since I think it is not possible using child packages...

Answer 1

In general, no; the second example works because the specification of Child is known when F is declared in Parent. In light of your previous question on this topic, it may be that you want a clean way to separate multiple implementations of a common specification. This related Q&A discusses two approaches: one using inheritance and the other using a library-based mechanism at compile-time.

Answer 2

I think what you are looking for is a private child package, this generally behaves in the same way as your nested example, but you cannot access it outside of its parent body.
Therefore :
private package Parent.Child is
type Child_Type is (A,B,C);
end Parent.Child;
...
package Parent is
procedure F;
end Parent;
...
with Ada.Text_Io;
with Parent.Child;
package body Parent is
procedure F is
begin
for A in Parent.Child.Child_Type'Range loop
Ada.Text_Io.Put_Line (Parent.Child.Child_Type'Image (A));
end loop;
end F;
end Parent;
Is ok to compile, but remember if you with the child in the parent spec (like you do with the parameter to F), you will get a circular dependency as children require their parents to exist first !
Therefore it really depends on what you want to be public to both the parent and the child whether this is an actual solution to your problem.

Answer 3

Julio, Types declared in a spec file (mytypes.ads)
package Mytypes is
type Fruit is (Apple, Pear, Pineapple, Banana, Poison_Apple);
subtype Safe_Fruit is Fruit range Apple .. Banana;
end Mytypes;
...
Withed it in several others :
with Mytypes;
package Parent is
function Permission (F : in Mytypes.Fruit) return Boolean;
end Parent;
...
package body Parent is
function Permission (F : in Mytypes.Fruit) return Boolean is
begin
return F in Mytypes.Safe_Fruit;
end Permission;
end Parent;
...
package Parent.Child is
procedure Eat (F : in Mytypes.Fruit);
end Parent.Child;
...
with Ada.Text_Io;
package body Parent.Child is
procedure Eat (F : in Mytypes.Fruit) is
begin
if Parent.Permission (F) then
Ada.Text_Io.Put_Line ("Eating " & Mytypes.Fruit'Image (F));
else
Ada.Text_Io.Put_Line ("Forbidden to eat " & Mytypes.Fruit'Image (F));
end if;
end Eat;
end Parent.Child;
...
with Mytypes;
with Parent.Child;
procedure Main is
begin
for I in Mytypes.Fruit'Range loop
Parent.Child.Eat (I);
end loop;
end Main;
It Compiles:
$ gnatmake main.adb
gcc-4.4 -c parent-child.adb
gnatbind -x main.ali
gnatlink main.ali
It Runs :
$ ./main
Eating APPLE
Eating PEAR
Eating PINEAPPLE
Eating BANANA
Forbidden to eat POISON_APPLE
Is this what you tried ?