AutoHotKey key SEQUENCE, not just single-key hotkey - keyboard-shortcuts

Question

I'm not stupid... really.
How do you map a key SEQUENCE (ie: Ctrl + Q , F) in AutoHotKey.
I've got Ctrl + Q down:
^q::
I've even got F:
f::
The examples in the help files even show how to do two keystrokes in a row:
Numpad0 & Numpad1::
But it just will not work with:
^q & f ::
Or any of these either:
LCtrl & q & f::
^q & ^f::
^q^f::
^qf::
How do I accomplish a Key SEQUENCE triggering something, when one of those keys is the Ctrl key? I looked into using a HOTSTRING instead, but couldn't work out how to include the Ctrl character, in that context!

Answer 1

Alright; The answer seems to be:
^q::
Input Key, L1
if Key=f
...some code here...
return

Answer 2

In case someone's looking for a similar thing, but actually want CtrlQ + CtrlF and only if Ctrl is held throughout (so, to some, this might seem like CtrlQ + F), then here's how to do that:
$Ctrl::Send {Ctrl Down}
$Ctrl UP::
ChordIsBroken := True
Send {Ctrl Up}
Return
^q::
ChordIsBroken := False
Input, OutputVar, L1 M
If (!ChordIsBroken && Asc(OutputVar) = 6)
{
MsgBox "Hello, World!"
}
Else
{
SendInput %OutputVar%
}
Return
See https://superuser.com/a/725303/145431 for my explanation.

Answer 3

Or you can do it like this:
q & f::
if GetKeyState("Control") {
; Do something
return
}
return
I think this is a bit more readable than using Input Key, L1 as in above.

Answer 4

This catches CTRL+F. If Q is held down at that moment, your code fires.
^f::
If GetKeyState("q", "p") {
MsgBox test
} Else {
Send ^f
}
return

Answer 5

The selected answer works fine, but I spend the whole night writing me own solution before I found this answer, so...
Here is my over engineered solution -
SequenceRegister() {
registeredHook := 0
inputLen := 0
actions := Map()
return SequenceClosure
SequenceClosure(seq := "", ActionCb := () => true) {
if (!registeredHook) {
h := InputHook("BI")
h.KeyOpt("{All}", "N")
h.OnKeyDown := KeyDownHandler
h.Start()
registeredHook := h
}
actionKey := actions.Count
actions.Set(actionKey, Action)
Action(hook, VK, SC) {
if (SubStr(seq, 1, inputLen) = hook.Input && inputLen < StrLen(seq)) {
return
}
if (hook.Input = seq && inputLen = StrLen(seq)) {
ActionCb()
return
}
actions.delete(actionKey)
if (actions.Count = 0) {
Send("{Blind}" . Format("{{}vk{:x}sc{:x}{}}", VK, SC))
hook.Stop()
return
}
}
}
KeyDownHandler(hook, VK, SC) {
inputLen++
for key, value in actions.Clone() {
value(hook, VK, SC)
}
}
}
Use it like this -
Capslock & s::{
CreateSequence := SequenceRegister()
CreateSequence("sleep", () => MsgBox("I sleep"))
CreateSequence("sleed", SleedCb)
SleedCb() {
MsgBox("I sleed")
}
}
This allows to register any number of sequences and if none of the sequences match - the pressed key is replayed.
Note, that this code works only in AHK v2