Finding and separating all parts in AutoTextList Field - vba

Question

I have documents that have AutoTextList fields. Unlike most fields, Fields(i).Code does not show the entire code. The Display Text / Literal Text does not show up when you display the field code nor does it report out in VBA.
I am trying to pull the components of this field and place into string variables.
The syntax of the field, when written, is:
{ AUTOTEXTLIST "Literal text" \s ["Style name"] \t ["Tip text"] }
I wrote the following macro to get a look at what can be found and how.
Sub LookAtAutoTextListField()
Dim i As Long
With ActiveDocument
For i = .Fields.Count To 1 Step -1
If .Fields(i).Type = wdFieldAutoTextList Then
Debug.Print "Display Text: " & .Fields(i).Result
Debug.Print "Code: " & .Fields(i).Code
End If
Next i
End With
End Sub
Here are four examples of the results:
1
Display Text: What I want
Code: AUTOTEXTLIST \s Normal \t ""How much""
2
Display Text: What I want
Code: AUTOTEXTLIST \s "Normal" \t ""How much""
3
Display Text: What I want
Code: AUTOTEXTLIST \s "Body Text" \t "Right-click to choose how much"
4
Display Text: What I want
Code: AUTOTEXTLIST \s "Body Text" \t ""How much""
I can easily put the Display text in a string.
The pop-up tip text can have slashes or not. When inserted using the insert field, it will have backslashes front and back. See all but example 3 above.
The style name may or may not have quotation marks around it. It must have them if the style name contains a space, but otherwise they are not required but can be used. See examples 1 and 2 above.
I would like to get the text between \s and \t stripping out quotation marks and the text following \t stripping out quotation marks and the backslashes.
I can find the location of the \s in the code using the Instr function and the left and right position of the \t in the code using Instr and InstrRev functions. I can get the length of what is reported for the code using the Len function.
I can use that information, together with the Left and Right functions to get the text between \s and \t (i.e. the Style) but need to strip out any Quotation marks which may or may not be present. I don't know how to do that.
I can do the same thing with the tip text, but don't know how to strip out any quotation marks and backslashes.

Answer 1

You could use code along the following lines (not well tested, e.g. I haven't checked what happns with an option value that starts with a " but has no terminating " - probably terminated by the end-of-field marker) as long as you know you are dealing with a "typical" field code, e.g. the sort that Word itself might create, where there is white space between the various elements of the field, the white space is all composed of regular spaces, and multi-word strings are enclosed by straight double quotation marks (chr(34)).
FWIW here I don't see quite what you describe when entering this field type from the field dialog box. I never see \t ""How much"". If I enter the tip text without quotation marks in the dialog box, I see \t "How much" and the quotation marks are not displayed in the tip. If I enter the tip text with quotation marks in the dialog box, I see \t "\"How much\"" and the quotation marks are displayed in the tip.
Sub testgetfieldparts()
' pass an autotextlistfield object
Call getAutotextlistFieldParts2(ActiveDocument.Fields(1))
End Sub
Sub getAutotextlistFieldParts(f As Word.Field)
Const FieldCodeName As String = "AUTOTEXTLIST"
Dim i As Long
Dim s As String
Dim StyleName As String
Dim TipText As String
If f.Type = WdFieldType.wdFieldAutoTextList Then
s = f.Code
i = InStr(1, UCase(s), FieldCodeName)
s = Trim(Mid(s, i + Len(FieldCodeName)))
i = InStr(1, LCase(s), "\s")
Debug.Print "Style Name: ";
If i = 0 Then
Debug.Print "No \s option specified"
Else
StyleName = OptionValue(s, i + 2)
If StyleName = "" Then
Debug.Print "\s option specified but no name specified"
Else
Debug.Print StyleName
End If
End If
i = InStr(1, LCase(s), "\t")
Debug.Print "Tip Text: ";
If i = 0 Then
Debug.Print "No \t option specified"
Else
TipText = OptionValue(s, i + 2)
If TipText = "" Then
Debug.Print "\t option specified but no text specified"
Else
Debug.Print TipText
End If
End If
Else
Debug.Print "Not an " & FieldCodeName & " field."
End If
End Sub
Function OptionValue(s As String, iStart As Long) As String
Dim c As String
Dim i As Long
Dim escape As Boolean
OptionValue = ""
escape = False
s = Trim(Mid(s, iStart))
c = Left(s, 1)
Select Case c
Case """"
For i = 2 To Len(s)
c = Mid(s, i, 1)
If escape Then
OptionValue = OptionValue & c
escape = False
Else
If c = """" Then
Exit For
Else
If c = "\" Then
escape = True
Else
OptionValue = OptionValue & c
End If
End If
End If
Next
Case "\" ' for now, assume this is the start of another option
'
Case Else
OptionValue = OptionValue & c
For i = 2 To Len(s)
c = Mid(s, i, 1)
If c = "\" Or c = " " Or c = """" Then
Exit For
Else
OptionValue = OptionValue & c
End If
Next
End Select
End Function
If you had to deal with what is actually allowed in a Word field code rather than what you will typically find, things get considerably more complicated, for at least the following reasons in Word's "field code language":
Word generally recognises 6 different Unicode characters as double quotation marks for enclosing strings, not just ". It doesn't recognise any single quotation marks for that purpose. You can use any of the 6 to start a string and any of the 6 to end one - they don't have to match in any way.
Word recognises at least 11 Unicode characters as "white space". The VBA Trim, LTrim and RTrim functions don't remove most of them.
Inside quoted strings, the backslash character \ generally acts as an escape character, so you can insert a \" in the middle of a string to get a " character. But outside quoted strings, backslash will generally be seen as the start of a new option and will act as a string terminator for any unquoted string.
You can put all sorts of non-text items in a field, e.g. inline images, content controls etc. It may not make sense in any given field to do that, but in a complete field parsing solution you might have to deal with such things. It isn't uncommon to use nested fields (e.g. you could specify the Style Name and Tip Text that way. In that case, the field result is generally as a "spaceless string" so even if the result contains spaces you do not have to put quotation marks around it. So you cannot treat the field result in the same way as you would treat its plain text result. There is more...
in some case you don't actually need any white space in the field. e.g. I think {AUTOTEXTLIST\sMyStyle\tImportantTip} would work. So a parser shouldn't rely on the presence of white space to separate tokens in the field.
Word doesn't always (ever?) prevent you from having multiple instances of the same option. In some cases that's deliberate (e.g. it's how you can include multiple books in a CITATION field.). But say you had two \t options in your AUTOTEXTLIST. In that case Word uses the first one unless no tip text is given, i.e. \t tip1 \t tip2 should display tip1 but \t \t tip2 will display tip2. AFAICS \s Style1 \s Style2 uses Style1 but I couldn't work out what \s \s Style2 was doing.
ANd there are doubtless exceptions to all that lot too. I have some code that deals with some of those issues but it isn't complete or well-tested.