find a right xslt for given data - xslt-1.0

Question

data xml form and conver and filtering some information...
using axes and following sibling...
-----------------------------Source XML------------------------ <FY2019Temperature>
<January>
<High>-1</High>
<Low>-9</Low>
</January>
<February>
<High>-1</High>
<Low>-9</Low>
</February>
<March>
<High>21</High>
<Low>9</Low>
</March>
<April>
<High>21</High>
<Low>9</Low>
</April>
<May>
<High>21</High>
<Low>9</Low>
</May>
<June>
<High>21</High>
<Low>9</Low>
</June>
<July>
<High>29</High>
<Low>18</Low>
</July>
<August>
<High>29</High>
<Low>18</Low>
</August>
<September>
<High>24</High>
<Low>12</Low>
</September>
<October>
<High>24</High>
<Low>12</Low>
</October>
<November>
<High>12</High>
<Low>-1</Low>
</November>
<December>
<High>-1</High>
<Low>-9</Low>
</December>
-----------------Expected Result---------------------------
Months Range,Temperature Range
January to February,-1 to -9
March to June,21 to 9
July to August,29 to 18
September to October,24 to 12
November,12 to -1
December,-1 to -9

Answer 1

The XSLT 3 approach outlined in the comment would be
<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
xmlns:xs="http://www.w3.org/2001/XMLSchema"
exclude-result-prefixes="#all"
expand-text="yes"
version="3.0">
<xsl:output method="text"/>
<xsl:template match="/*">
<xsl:text>Months range, temperature range
</xsl:text>
<xsl:for-each-group select="*" composite="yes" group-adjacent="High, Low">{name()}{(' to ' || name(current-group()[last()]))[current-group()[2]]}, {High} to {Low}
</xsl:for-each-group>
</xsl:template>
</xsl:stylesheet>

Answer 2

Solution-1
<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
xmlns:xs="http://www.w3.org/2001/XMLSchema"
exclude-result-prefixes="xs"
version="2.0">
<xsl:output encoding="UTF-8" method="text" />
<xsl:variable name="Linefeed" select="'
'"/>
<xsl:template match="/">
<xsl:value-of select="string-join(('Months Range','Temperature Range'),
',')"/>
<xsl:value-of select="$Linefeed"/>
<xsl:for-each-group select="/FY2019Temperature/*" group-
adjacent="string-join((High,Low),'|')">
<xsl:for-each select="current-group()">
<xsl:choose>
<xsl:when test="count(current-group()) gt 1">
<xsl:if test="position()=1">
<xsl:value-of select="name()"/>
<xsl:text> to </xsl:text>
</xsl:if>
<xsl:if test="position()=last()">
<xsl:value-of select="name()"/>
<xsl:text>, </xsl:text>
</xsl:if>
</xsl:when>
<xsl:otherwise>
<xsl:value-of select="name()"/>
<xsl:text>, </xsl:text>
</xsl:otherwise>
</xsl:choose>
</xsl:for-each>
<xsl:value-of select="High"/>
<xsl:text> to </xsl:text>
<xsl:value-of select="Low"/>
<xsl:value-of select="$Linefeed"/>
</xsl:for-each-group>
</xsl:template>
</xsl:stylesheet>