SAS: Importing Fixed Width file w Infile function and where clause - file-io

Question

I have two SAS data steps that import a text file called "Provider_Master.txt" using a fixed Width approach. The first data step pulls the entire "Provider_Master.txt" file into SAS as a dataset called "t_Pvdr_Mstr" and the next data step retains only the parts of the file that I need, which is RecordTypes that have a "T" in the RecordType field. This approach works well enough but is very inefficient because the file is over 2 gigs large. Once I strip away all the lines that don't have a "T" the RecordTypes field, the file is less than 400 KBs. It would make alot more sense to only import the lines I need instead of importing the entire text file but I'm not sure how to contrain the import to only pull down RecordTypes that have a "T". Below is an example of the code I'm currently using....
data Grid.t_Pvdr_Mstr ;
infile "C:\SASData\Provider_Master.txt " truncover;
input
Insurer $ 1-4
RecordType $ 5-7
Actions $ 8-8
Pvdr $ 9-18
Type $ 19-19
Name $ 20-58
Bus_Type_Code $ 59-61
Bus_Date $ 62-69
Address1 $ 70-129
Address2 $ 130-189
City $ 190-219
State $ 220-221
Zip $ 222-230
County $ 231-260
Country $ 261-263
Phone $ 264-274;
run;
data Grid.t_Pvdr_Mstr;
set Grid.t_Pvdr_Mstr;
where RecordType = 'T';
run;

Answer 1

Add an if statement to prevent it from outputting unneeded records. That way you do not need to create a second step with a where statement.
data Grid.t_Pvdr_Mstr ;
infile "C:\SASData\Provider_Master.txt " truncover;
input
Insurer $ 1-4
RecordType $ 5-7
Actions $ 8-8
Pvdr $ 9-18
Type $ 19-19
Name $ 20-58
Bus_Type_Code $ 59-61
Bus_Date $ 62-69
Address1 $ 70-129
Address2 $ 130-189
City $ 190-219
State $ 220-221
Zip $ 222-230
County $ 231-260
Country $ 261-263
Phone $ 264-274;
if(RecordType = 'T');
run;
An if without then statement effectively says "Do not pass this line unless this is true." Since output is implied at the run boundary, we're only outputting records where RecordType = 'T'.