Add index when same column value - awk

Question

I have this two columns file :
ctg0F chr_1
ctg1F chr_2
ctg2F chr_3
ctg3F chr_4
ctg4F chr_5
ctg5F chr_6
ctg6F chr_4
ctg7F chr_7
ctg8F chr_8
The first column has different values. I'd like to add an index only for the repeated values in the second column. Here chr4 appears twice, and so :
ctg0F chr_1
ctg1F chr_2
ctg2F chr_3
ctg3F chr_4_1
ctg4F chr_5
ctg5F chr_6
ctg6F chr_4_2
ctg7F chr_7
ctg8F chr_8
I do this :
awk '{ if (++count[$2]>1) print $1,$2"_"count[$2]; else print $1,$2"_"count[$2]}'
But this even adds index "_1" for the unique values.
Any help?

Answer 1

With your shown samples in single awk using its END block capabilities please try following awk code.
awk '
{
lineValue[FNR]=$0
secField[$2]++
lineSecondValue[FNR]=$2
}
END{
for(i=1;i<=FNR;i++){
if(secField[lineSecondValue[i]]>1){
print lineValue[i]"_"++currentSecVal[lineSecondValue[i]]
}
}
}
' Input_file

Answer 2

$ awk '
NR==FNR { tot[$2]++; next }
{ print $0 (tot[$2]>1 ? "_" (++cnt[$2]) : "") }
' file file
ctg0F chr_1
ctg1F chr_2
ctg2F chr_3
ctg3F chr_4_1
ctg4F chr_5
ctg5F chr_6
ctg6F chr_4_2
ctg7F chr_7
ctg8F chr_8

Answer 3

This 2 phase awk approach should work for you that computes and stores frequency of 2nd column in 1st phase and then adds a suffix when frequency is greater than one.
awk 'NR == FNR {++fq[$2]; next}
fq[$2] > 1 {$0 = $0 "_" ++ind[$2]} 1' file file
ctg0F chr_1
ctg1F chr_2
ctg2F chr_3
ctg3F chr_4_1
ctg4F chr_5
ctg5F chr_6
ctg6F chr_4_2
ctg7F chr_7
ctg8F chr_8

Answer 4

Use this Perl in-line script:
perl -lane '
$total{ $F[-1] }++;
last LINE if eof;
END {
while ( <> ) {
chomp;
#fields = split;
$_ = join "_", $_, ++$cnt{ $fields[-1] } if $total{ $fields[-1] } > 1;
print;
}
}' input.txt input.txt
$total{ $F[-1] }++; : Count the total number of occurrences of the last column strings (chr...).
last LINE if eof; : Stop processing the file in first command line argument (input.txt) and skip to processing file in the second argument (which is also input.txt).
while ( <> ) { ... } : Read the current input file (input.txt) line by line, storing the current line in $_ variable.
chomp : Strip the terminal newline from $_.
$_ = join "_", $_, ++$cnt{ $fields[-1] } if $total{ $fields[-1] } > 1; : If the total number of occurrences of the last field is greater than 1, then increment the current number of occurrences by 1, and prepend it to the current line.
print; : Print the resulting current line.
The Perl one-liner uses these command line flags:
-e : Tells Perl to look for code in-line, instead of in a file.
-n : Loop over the input one line at a time, assigning it to $_ by default.
-l : Strip the input line separator ("\n" on *NIX by default) before executing the code in-line, and append it when printing.
-a : Split $_ into array #F on whitespace or on the regex specified in -F option.
SEE ALSO:
perldoc perlrun: how to execute the Perl interpreter: command line switches
perldoc perlvar: Perl predefined variables

Answer 5

{m,g,n}awk '(_ = NF)*(FNR == NR) ? !++__[$_] :
__[$_]<_ || $!_=$!_ "_"++___[$_] ' file file
ctg0F chr_1
ctg1F chr_2
ctg2F chr_3
ctg3F chr_4_1
ctg4F chr_5
ctg5F chr_6
ctg6F chr_4_2
ctg7F chr_7
ctg8F chr_8