Continuous Press on Command Button - vba

Question

If my mouse is pressed continuously on the Spin Button, the increment keeps happening. However, the Command Button requires me to click again and again. How can I have the Command Button behave in a similar fashion to that of a Spin Button?
Private Sub CommandButton2_Click()
Label1.Caption = Int(Label1.Caption) + 10
End Sub
Private Sub spbSpinButton_Change()
spbSpinButton.Min = 100
spbSpinButton.Max = 200
spbSpinButton.SmallChange = 10
Label1.Caption = spbSpinButton.Value
End Sub

Answer 1

You can't do it with the Click event, but if you keep track of MouseUp and MouseDown you can trigger a loop. Something like this:
Add a module
Put this code in the module. Give the module any name, but it is referred to as Module1 below.
#If VBA7 Then
Public Declare PtrSafe Sub Sleep Lib "kernel32" (ByVal dwMilliseconds As LongPtr) 'For 64 Bit Systems
#Else
Public Declare Sub Sleep Lib "kernel32" (ByVal dwMilliseconds As Long)
#End If
In your Form
Put this in your Module
Dim ButtonDown As Boolean
Private Sub UserForm_Activate()
ButtonDown = False
End Sub
Private Sub CommandButton1_MouseDown(ByVal Button As Integer, ByVal Shift As Integer, ByVal X As Single, ByVal Y As Single)
ButtonDown = True
IncrementCounter
End Sub
Private Sub CommandButton1_MouseUp(ByVal Button As Integer, ByVal Shift As Integer, ByVal X As Single, ByVal Y As Single)
ButtonDown = False
End Sub
Sub IncrementCounter()
If ButtonDown Then
Label1.Caption = Int(Label1.Caption) + 10
DoEvents
Module1.Sleep 100
IncrementCounter
End If
End Sub
The Module1.Sleep 100 says wait 100 milliseconds. Adjust to your need.