Closing Excel after inactivity, even in edit mode - vba

Question

I'm not sure this is possible I didn't really find anything when I was searching for an answer online. I have a macro in place where it will close after 5 minutes of inactivity. Works like a charm except when the user is editing a cell the timer does not start, therefore it will not close because of this. Is there a way for excel to have a timer for how long the user is in edit mode then it will take them out of it. Once out of edit mode the macro will start the 5 minutes of inactivity. Any help is greatly appreciated!
HERE IS THE WORKBOOK MODULE
Private Sub Workbook_BeforeClose(Cancel As Boolean)
Me.Saved = True
End Sub
Private Sub Workbook_Open()
start_Countdown
End Sub
Private Sub Workbook_SheetChange(ByVal Sh As Object, ByVal Target As Range)
stop_Countdown
start_Countdown
End Sub
HERE IS THE STANDARD MODULE
Option Explicit
Public Close_Time As Date
Sub start_Countdown()
Close_Time = Now() + TimeValue("00:05:00")
Application.OnTime Close_Time, "close_WB"
End Sub
Sub stop_Countdown()
Application.OnTime Close_Time, "close_WB", , False
End Sub
Sub close_wb()
ThisWorkbook.Close True
End Sub

Answer 1

You will need some kind of process monitor/task terminator outside of VBA to do this because VBA is "locked out" while the user is in input mode.

Answer 2

You can try this:
Public Declare Function SetTimer Lib "user32" ( _
ByVal HWnd As Long, _
ByVal nIDEvent As Long, _
ByVal uElapse As Long, _
ByVal lpTimerFunc As Long) As Long
Public Declare Function KillTimer Lib "user32" ( _
ByVal HWnd As Long, _
ByVal nIDEvent As Long) As Long
Public TimerID As Long
Public TimerSeconds As Single
Sub StartTimer()
TimerSeconds = 5*60 ' how often to "pop" the timer (5 minutes in the example).
TimerID = SetTimer(0&, 0&, TimerSeconds * 1000&, AddressOf TimerProc)
End Sub
Sub EndTimer()
On Error Resume Next
KillTimer 0&, TimerID
End Sub
Sub TimerProc(ByVal HWnd As Long, ByVal uMsg As Long, _
ByVal nIDEvent As Long, ByVal dwTimer As Long)
' call here whatever you want to call
End Sub
This always work even in edit mode, dont forget to call StartTimer to start and EndTimer before quitting...