sum of column based on another column will show on another - vb.net

Question

Can you help me with my DataGridView? I need to show sum of column based on another column.
For example, I have Part number 1,2,3. QTY for PN is always 1 because of the serial number given.
PN 1 has 10qty (10rows). I need to sum it based on that PN and put the sum value at the end cell. Please see below sample:
It is excel I know, but just please bear with me pretend it is DataGridView.
Total sum is based on sum of cost for the same PN.

Answer 1

You will need to follow the link in my comment, and do some manipulation in the DataGridView_Paint event. I have done that below.
I made a class to hold your data called Model. I also used DataBinding to put that data into the DataGridView. Your method for holding and applying the data might be different, but this works well.
Public Class Form1
Private data As List(Of Model)
Private dataGroups As IEnumerable(Of (PN As Integer, TotalSum As Double, Count As Integer))
Private Sub Form1_Load(sender As Object, e As EventArgs) Handles MyBase.Load
data = New List(Of Model) From {
New Model(1, 1, 11.5),
New Model(1, 12, 2),
New Model(1, 13, 10.4),
New Model(1, 14, 12.3),
New Model(1, 15, 10),
New Model(1, 16, 10),
New Model(2, 17, 5),
New Model(2, 18, 1),
New Model(2, 19, 7),
New Model(2, 20, 2),
New Model(2, 21, 4),
New Model(3, 22, 4),
New Model(3, 23, 6),
New Model(3, 24, 3),
New Model(3, 25, 7)}
DataGridView1.DataSource = data
dataGroups = data.GroupBy(Function(d) d.PN).Select(Function(g) (g.Key, g.Sum(Function(g1) g1.Cost), g.Count()))
Dim textBoxColumn = New DataGridViewTextBoxColumn() With {.HeaderText = "Total Sum"}
DataGridView1.Columns.Add(textBoxColumn)
End Sub
Private Sub DataGridView1_Paint(sender As Object, e As PaintEventArgs) Handles DataGridView1.Paint
If DataGridView1.DataSource IsNot Nothing Then
Dim columnIndex = DataGridView1.Columns.Count - 1
Dim counter As Integer = 0
Dim index As Integer = 0
Dim rowDisplayRectangle = DataGridView1.GetRowDisplayRectangle(0, True)
Dim headerCell = DataGridView1.Columns(0).HeaderCell
Dim defaultCellStyle = DataGridView1.DefaultCellStyle
Dim font = DataGridView1.Font
For Each dataGroup In dataGroups
Dim columnDisplayRectangle = DataGridView1.GetColumnDisplayRectangle(columnIndex, True)
Dim totalSumString = dataGroup.TotalSum.ToString()
Dim rect As New Rectangle(
columnDisplayRectangle.X,
columnDisplayRectangle.Y + headerCell.ContentBounds.Height + counter * rowDisplayRectangle.Height + 8,
columnDisplayRectangle.Width - 1,
(rowDisplayRectangle.Height + 1) * dataGroup.Count - 7 + index)
e.Graphics.FillRectangle(New SolidBrush(defaultCellStyle.BackColor), rect)
Dim point As New Point(
columnDisplayRectangle.X + columnDisplayRectangle.Width - e.Graphics.MeasureString(totalSumString, font).Width - 8,
rect.Y + rect.Height - e.Graphics.MeasureString(totalSumString, font).Height - (rowDisplayRectangle.Height - e.Graphics.MeasureString(totalSumString, font).Height) / 2)
e.Graphics.DrawString(totalSumString, font, New SolidBrush(defaultCellStyle.ForeColor), point)
counter += dataGroup.Count
index += 1
Next
End If
End Sub
End Class
Public Class Model
Public Sub New(pn As Integer, serial As Integer, cost As Double)
Me.PN = pn
Me.Serial = serial
Me.Cost = cost
End Sub
Public Property PN As Integer
Public Property Serial As Integer
Public Property Cost As Double
End Class
It is not straightforward and is not handled out of the box. You also may need to fool with the integers in the draw event if you find items not aligning with different fonts. I don't have time to do that.