Different footer on page 1 and rest - vba

Question

I have got a document that uses the same footer for all pages but I want to change the layout and have different footer on the first page and all the rest of the pages.
Sadly I have no clue how to change the footer. I think I have to use two different footer but where do I address the correct page?
Public Sub footer()
Set p_image = ActiveDocument.Shapes.AddPicture(FileName:= _
p_path & "BwK_" & INIT.p_CO & "_XX_XX_FL_2020.jpg", _
LinkToFile:=True, _
SaveWithDocument:=False, _
Width:=MillimetersToPoints(170), _
Height:=MillimetersToPoints(20), _
Anchor:=ActiveDocument.Sections(1).Headers(wdHeaderFooterFirstPage).Range)
With p_image
.RelativeHorizontalPosition = wdRelativeHorizontalPositionPage
.Left = MillimetersToPoints(20)
.RelativeVerticalPosition = wdRelativeVerticalPositionPage
.Top = MillimetersToPoints(275)
End With
End Sub

Answer 1

The following will set all sections in a document to have a different first page for headers AND footers.
Sub HeaderFirstPageOn()
' Charles Kenyon 2021-12-29
' Set Different First Page for Headers and Footers in all sections
Dim iSections As Long
Dim iCount As Long
Let iSections = ActiveDocument.Sections.Count
For iCount = 1 To iSections
Let ActiveDocument.Sections(iCount).PageSetup.DifferentFirstPageHeaderFooter = True
Next iCount
End Sub
Here is a macro that sets this for the first section only.
Sub HeaderFirstPageOn1()
' Charles Kenyon 2021-12-29
' Set Different First Page for Headers and Footers in first section only
Let ActiveDocument.Sections(1).PageSetup.DifferentFirstPageHeaderFooter = True
End Sub
Here is a link to my writing on header and footer settings. Note that this is a Section setting, not a page or document setting and that it applies to both headers and footers. So, if you have footer content, you may need to duplicate it for the first-page header.

Answer 2

Thank you for your help and extensive documentation on your page, it helped me finding the correct answer:
Public Sub footer2()
    Set p_image = ActiveDocument.Shapes.AddPicture(FileName:= _
        p_path & "BwK_" & INIT.p_CO & "_XX_XX_FL_2022_Primary.png", _
        LinkToFile:=True, _
        SaveWithDocument:=False, _
        Width:=MillimetersToPoints(170), _
        Height:=MillimetersToPoints(20), _
        Anchor:=ActiveDocument.Sections(1).Headers(wdHeaderFooterPrimary).Range)
    With p_image
        .RelativeHorizontalPosition = wdRelativeHorizontalPositionPage
        .Left = MillimetersToPoints(20)
        .RelativeVerticalPosition = wdRelativeVerticalPositionPage
        .Top = MillimetersToPoints(275)
    End With
End Sub
In fact the document only uses one section and so I only had to change wdHeaderFooterFirstPage to wdHeaderFooterPrimary.