MSWord vba chart location - vba

Question

Building a Word report using vba that will include a chart. Problem is finding out how to insert chart at specific point int report. No matter what I try the chart ends up on page 1. I need it to e.g. be placed in page 2. See below for code. Works perfectly apart from chart placement
Public Function gbAuditReportGraphs(ByVal lAuditID As Long) As Boolean
'
' NRE 07-Oct-2017
'
' Purpose : Prototype graphs in Audit
' See also
' Mantis 2250
' https://msdn.microsoft.com/en-us/library/office/ff629397(v=office.14).aspx
' Note : This version outputs to a word document
' Mods
Dim objChart As chart
Dim chartWorkSheet As Excel.Worksheet
Dim rs As New ADODB.Recordset
Dim ssql As String
Dim chSeries As Series
Dim rng As Range
Dim i As Integer
Dim clsAudit_ As New clsAudit
Dim clsRig_ As New clsRig
Dim bOk As Boolean
Dim vRigName As Variant
On Error GoTo eh
' Initialise function as false
gbAuditReportGraphs = False
clsAudit_.AuditID = lAuditID
bOk = clsAudit_.mbLoad
clsRig_.RigID = clsAudit_.RigID
bOk = clsRig_.mbLoad
vRigName = clsRig_.RigName
ssql = " SELECT cl.checklistdesc" _
& " , COUNT(*) AS nccount " _
& " FROM tbltask t " _
& " , tblchecklist cl" _
& " WHERE cl.auditid=t.auditid" _
& " AND cl.checklistid = t.checklistid" _
& " AND cl.auditid = " & lAuditID _
& " AND t.tasktype = '" & gsO & "'" _
& " AND t.taskstatus>0" _
& " GROUP BY cl.checklistdesc" _
& " ORDER BY 1"
Debug.Print "modADCForms.gbAuditReportGraphs, ssql = " & ssql
' Declare the Word Application and Document
Set mobjWordApp = New Word.Application
Set mobjWordDoc = mobjWordApp.Documents.Add
mobjWordDoc.SetCompatibilityMode wdWord2010
' Add page numbers
With mobjWordDoc.Sections(1)
.Footers(wdHeaderFooterPrimary).PageNumbers.Add PageNumberAlignment:=wdAlignPageNumberRight, FirstPage:=True
'Add Date
.Footers(wdHeaderFooterPrimary).Range.InsertBefore Format(Date, "dd-MMM-YYYY") & Chr(9) & Chr(9)
.Footers(wdHeaderFooterPrimary).Range.Paragraphs.Alignment = wdAlignParagraphLeft
.Footers(wdHeaderFooterPrimary).Range.Font.Name = "ForzaMedium"
.Footers(wdHeaderFooterPrimary).Range.Font.Size = 12
End With
Debug.Print "modADCForms.gbAuditReportGraphs,0"
modADCForms.gInserttext wdStyleNormal, "Page 1", wdColorBlack
modADCForms.gInsertPage
modADCForms.gInserttext wdStyleNormal, "Page 2", wdColorBlack
Debug.Print "modADCForms.gbAuditReportGraphs 1"
Set rng = mobjWordDoc.Range
With rng
.Collapse wdCollapseEnd
.Collapse Direction:=wdCollapseEnd
.InsertParagraphAfter
.Collapse Direction:=wdCollapseEnd
End With
' Set objChart = mobjWordDoc.Shapes.AddChart(xl3DPie, , 60, , 450, rng) -- type mismatch
Set objChart = mobjWordDoc.Shapes.AddChart.chart
objChart.ChartType = xlPie
objChart.HasLegend = False
Debug.Print "modADCForms.gbAuditReportGraphs 2"
' Create chart worksheet
Set chartWorkSheet = objChart.ChartData.Workbook.Worksheets(1)
' Add a header
chartWorkSheet.Range("Table1[[#Headers],[Series 1]]").FormulaR1C1 = vRigName & " Non-Conformance Distribution"
rs.Open ssql, CurrentProject.Connection, adOpenStatic, adLockReadOnly
If Not rs.EOF Then
i = 2
Do While Not rs.EOF()
chartWorkSheet.Range("A" & i).FormulaR1C1 = rs.Fields("checklistdesc")
chartWorkSheet.Range("B" & i).FormulaR1C1 = rs.Fields("nccount")
i = i + 1
rs.MoveNext
Loop
End If
rs.Close
chartWorkSheet.ListObjects("Table1").Resize chartWorkSheet.Range("A1:B" & i - 1)
' Configure chart to show the values
With objChart
With .SeriesCollection(1)
.HasDataLabels = True
.DataLabels.ShowValue = True
.HasLeaderLines = True
.DataLabels.ShowCategoryName = True
End With
End With
' set the fonts
Debug.Print " Setting the fonts of the labels ..1."
objChart.ChartArea.Font.Size = 9
objChart.ChartArea.Font.Name = gsFontForzaMedium
' Set the location of the chart
With objChart.Parent
.Height = 450
.Top = 60
End With
' show the document
mobjWordApp.visible = True
' Close the spreadsheet chart object
objChart.ChartData.Workbook.Application.Quit
' Clear the objects
Set rs = Nothing
Set clsRig_ = Nothing
Set clsAudit_ = Nothing
' Set function to status OK
gbAuditReportGraphs = True
ex:
Exit Function
eh:
gError "Problem creating audit report graphs", "modADCForms", "gbAuditReportGraphs", Err, Error
Resume ex
End Function

Answer 1

Cindy, I have taken your value advice, and fixed it :)
Pass in parameter of the range
Public Function gbAuditReportGraphs(ByVal lAuditID As Long, rng As Range) As Boolean
Create chart as an inline shape
Set objChart = mobjWordDoc.InlineShapes.AddChart.Chart
objChart.ChartType = xlPie
Set the size with code such as
With mobjWordApp.ActiveDocument
.InlineShapes(1).Height = 450
.InlineShapes(1).Width = 400
End With
Copy and paste chart into the specified range
objChart.Copy
rng.Paste
Delete the original
objChart.Delete
I could find no other advice on how to do this; perhaps this post will help others.

Answer 2

One tip to make your solution more robust: Generally, you can't be sure that the InlineShape you insert is the first in the document, so ActiveDocument.InlineShapes(1) isn't reliable. Better to declare an InlineShape object and assign the InlineShape belonging to the chart to it, so you can be sure you're working with the right InlineShape:
'1.Pass in parameter of the range
Public Function gbAuditReportGraphs(ByVal lAuditID As Long, _
rng As Range) As Boolean
Dim objChart as Word.Chart
Dim objInlineShape as Word.InlineShape
'2.Create chart as an inline shape
Set objChart = mobjWordDoc.InlineShapes.AddChart.Chart
objChart.ChartType = xlPie
'3.Set the size with code such as
Set objInlineShape = objChart.Parent
With objInlineShape
.Height = 450
.Width = 400
End With
'4.Copy and paste chart into the specified range
objChart.Copy
rng.Paste
'5.Delete the original
objChart.Delete
End Function