VBA - Syntax error with TRANSFORM in SQL statement - sql

Question

I'm here to ask you for help because, following various experiments with ADO, I have a problem that I can't solve.
I believe I have done everything right but VBA informs me that I have committed a syntax error in transform education
I have checked everything well and I didn't notice mistakes, also because the same query performed on Access works well.
The purpose is that the query returns this result:
If I run a very similar query without join I have no problems and everything works but if I use the join on the worksheet "months" the syntax problem emerges.
Would you be so kind to suggest where I'm wrong?
Thank you very much for support.
Here the file:
https://www.dropbox.com/s/2isoyahnsmvcr2k/Errore_TRANSFORM.xlsb?dl=0
Here my code:
Sub generaRicavi()
Dim RS As New ADODB.Recordset
Dim conn As String, SQL As String
Application.ScreenUpdating = False
conn = "Provider=Microsoft.ACE.OLEDB.12.0;Data Source=" & ThisWorkbook.FullName & "; Jet OLEDB:Bypass ChoiceField Validation =True;Extended Properties='Excel 12.0 Xml;HDR=YES;IMEX=1'"
SQL = "TRANSFORM Sum(Foglio1$.RICAVI)" _
& " SELECT Year([Foglio1$].[DATA])" _
& " FROM MESI$ LEFT JOIN Foglio1$ ON MESI$.MESE = Month([Foglio1$].[DATA])" _
& " GROUP BY Year([Foglio1$].[DATA])" _
& " ORDER BY Year([Foglio1$].[DATA]), MESI$.MESE" _
& " PIVOT MESI$.MESE;"
RS.Open SQL, conn, adOpenStatic, adLockReadOnly
With Foglio2
.Range("A3").CurrentRegion.ClearContents
.Range("A3:M3") = Array("ANNO","GENNAIO", "FEBBRAIO", "MARZO", "APRILE", "MAGGIO", "GIUGNO", "LUGLIO", "AGOSTO", "SETTEMBRE", "OTTOBRE", "NOVEMBRE", "DICEMBRE")
.Range("A4").CopyFromRecordset RS
End With
RS.Close
Application.ScreenUpdating = True
Set RS = Nothing
End Sub

Answer 1

I found the solution.
Indeed there were syntax errors in the query. The square brackets between worksheets and table fields were missing.
The code that works is this:
Sub generaRicavi()
Dim RS As New ADODB.Recordset
Dim conn As String, SQL As String
Application.ScreenUpdating = False
conn = "Provider=Microsoft.ACE.OLEDB.12.0;Data Source=" & ThisWorkbook.FullName & "; Jet OLEDB:Bypass ChoiceField Validation =True;Extended Properties='Excel 12.0 Xml;HDR=YES;IMEX=1'"
SQL = "TRANSFORM Sum(Foglio1$.RICAVI)" _
& " SELECT Year([Foglio1$].[DATA])" _
& " FROM [MESI$] LEFT JOIN [Foglio1$] ON [MESI$].[MESE] = Month([Foglio1$].[DATA])" _
& " GROUP BY Year([Foglio1$].[DATA])" _
& " ORDER BY Year([Foglio1$].[DATA]), [MESI$].[MESE]" _
& " PIVOT [MESI$].[MESE];"
RS.Open SQL, conn, adOpenStatic, adLockReadOnly
With Foglio2
.Range("A3").CurrentRegion.ClearContents
.Range("A3:M3") = Array("ANNO", "GENNAIO", "FEBBRAIO", "MARZO", "APRILE", "MAGGIO", "GIUGNO", "LUGLIO", "AGOSTO", "SETTEMBRE", "OTTOBRE", "NOVEMBRE", "DICEMBRE")
.Range("A4").CopyFromRecordset RS
End With
RS.Close
Application.ScreenUpdating = True
Set RS = Nothing
End Sub