Reiterating Sub TextBox1_Change() efficiently - vba

Question

Sub TextBox19_Change()
If Len(TextBox19.Value) = 4 Then TextBox19.Value = Mid(TextBox19.Value, 1, 3)
End Sub
Sub TextBox18_Change()
If Len(TextBox18.Value) = 4 Then TextBox18.Value = Mid(TextBox18.Value, 1, 3)
End Sub
Sub TextBox17_Change()
If Len(TextBox17.Value) = 4 Then TextBox17.Value = Mid(TextBox17.Value, 1, 3)
End Sub
Sub TextBox16_Change()
If Len(TextBox16.Value) = 4 Then TextBox16.Value = Mid(TextBox16.Value, 1, 3)
End Sub
How can I rephrase the above so that we don't have to duplicate the sub-routines for 100+ TextBoxes? There are more codes than just changing the textbox's value to its first 3 characters. I would appreciate a general efficient code. Thank you.
Edit: This isn't on a form. This is on PowerPoint Slides.

Answer 1

I wasn't sure if you're using form textboxes here, but you could also use event sinking.
So create a class clsCustomText like so
Private WithEvents t As msforms.TextBox
Private Const lMaxLength As Long = 3
Public Sub Init(tIn As msforms.TextBox)
Set t = tIn
End Sub
Private Sub t_Change()
If Len(t.Value) > lMaxLength Then t.Value = Left(t.Value, lMaxLength)
End Sub
Then in a normal module, somewhere to hold them
Public colCustomTextboxes As Collection
and then in the form like so, i did mine on click, so i can test. You'd need to move to initialize.
Private Sub UserForm_Click()
Dim c As Control
Dim t As clsCustomText
Set colCustomTextboxes = New Collection
For Each c In Me.Controls
If TypeOf c Is msforms.TextBox Then
Set t = New clsCustomText
t.Init c
colCustomTextboxes.Add t, c.Name
End If
Next c
End Sub