search all columns of listview - vb.net

Question

Good day.
Could someone tell me how I search through all the columns of a listview?
At the moment I have a code that only searches the first column (with index 0).
Dim ItemsList As New List(Of ListViewItem)
After filling the listview:
ItemsList.AddRange(ListView1.Items.Cast(Of ListViewItem))
Well, the selection (search) of values ​​by the text field itself:
Private Sub TxtSearchLog_TextChanged(sender As Object, e As EventArgs)
Dim showitems As New List(Of ListViewItem)
For Each i As ListViewItem In ItemsList
If i.Text.ToLower.Contains(TxtSearchLog.Text.ToLower.Trim) Then
showitems.Add(i)
End If
Next
ListView1.Items.Clear()
ListView1.Items.AddRange(showitems.ToArray)
End Sub

Answer 1

Private allItems As New List(Of ListViewItem)
Private Sub TextBox1_TextChanged(sender As Object, e As EventArgs) Handles TextBox1.TextChanged
Timer1.Stop()
Timer1.Start()
End Sub
Private Sub Timer1_Tick(sender As Object, e As EventArgs) Handles Timer1.Tick
Timer1.Stop()
Dim searchText = TextBox1.Text.Trim()
Dim items = allItems.Where(Function(lvi) lvi.SubItems.Cast(Of ListViewItem.ListViewSubItem).Any(Function(lvsi) lvsi.Text.IndexOf(searchText, StringComparison.CurrentCultureIgnoreCase) <> -1)).ToArray()
ListView1.Items.Clear()
ListView1.Items.AddRange(items)
End Sub
Firstly, you should not filter on the TextChanged event itself. If the user wants to search for a string of ten characters, your code would filter ten times when all but the last were useless. Instead, you should use a Timer with a fairly short Interval that you start/restart each time the Text changes and then only filter when the Timer Ticks. That way, you won't be filtering multiple times while the user is typing. You can experiment to get the best Interval value so that the user doesn't have to wait too long for the filter to happen but also doesn't have to type really quickly to avoid spurious filters.
As for the actual filtering, this code uses LINQ to do that. The Where function is what does the filtering, just like a WHERE clause in SQL. In this case, the result includes only those items that match the condition specified in the Where call. That condition is that the Text of any subitem contains the specified search text. Note that I have actually used a proper case-insensitive comparison, rather than using the hack of changing the case of the text. That hack will generally work and, I think, will always work in English but there are some cases in some languages where it won't work, so it is generally discouraged.
Unfortunately, the .NET Framework version of String.Contains cannot do case-insensitive comparisons, so you have to use IndexOf instead. If you're targeting .NET Core (including .NET 5.0 or later) then you do have an overload of Contains that will take a StringComparison argument.
For the record, if you wanted to modify your existing code as little as possible then you could just change this:
If i.Text.ToLower.Contains(TxtSearchLog.Text.ToLower.Trim) Then
to this:
If i.SubItems.Cast(Of ListViewItem.ListViewSubItem).Any(Function(lvsi) lvsi.Text.ToLower.Contains(TxtSearchLog.Text.ToLower.Trim)) Then

Answer 2

I have looped through all the items and subitems searching for the text. If the text is found in a ListViewItem, it is added to the list and the inner For is exited.
Private Function Search(SearchText As String) As List(Of ListViewItem)
Dim FoundItems As New List(Of ListViewItem)
For Each item As ListViewItem In lvCoffee.Items
For Each si As ListViewItem.ListViewSubItem In item.SubItems
If SearchText = si.Text Then
FoundItems.Add(item)
Exit For
End If
Next
Next
Return FoundItems
End Function