How to add user input to array list - vb.net

Question

the program is supposed to take the text in from the text boxes, combine it into a NewCustomer element, and then display it in a listbox. Below is the code i'm supposed to add to, i've tried lstCustomer.add(txtFirstname.text) but it turned to be an error. Thanks in advance for helping.
Public Class Form1
Private myCustomers As New ArrayList
Public ReadOnly Property SelectedCustomer As Customer
Get
Dim index As Integer = lstCustomer.SelectedIndex
If index <> -1 Then
Return lstCustomer.Items(index)
Else
Return Nothing
End If
End Get
End Property
Public Sub NewCustomer(ByVal fn As String, ByVal ln As String, ByVal a As Integer, ByVal e As String)
Dim temp As Customer
temp.FirstName = fn
temp.LastName = ln
temp.Age = a
temp.Email = e
myCustomers.Add(temp)
Me.lstCustomer.Items.Add(temp)
End Sub
Private Sub BtnTest_Click(sender As Object, e As EventArgs) Handles BtnTest.Click
NewCustomer("Homer", "Simpson", 40, "HSimpson#springf.com")
NewCustomer("Bruce", "Banner", 44, "green#giant.com")
End Sub
Public Sub displayCustomer(ByVal temp As Customer)
Me.TxtName.Text = temp.name
Me.TxtFirstName.Text = temp.FirstName
Me.TxtLastName.Text = temp.LastName
Me.TxtAge.Text = temp.Age
Me.TxtEmail.Text = temp.Email
End Sub
Private Sub BtnAdd_Click(sender As Object, e As EventArgs) Handles BtnAdd.Click
lstCustomer.add(TxtFirstName.Text And TxtLastName.Text And TxtEmail.Text And TxtAge.Text)
End Sub

Answer 1

I suggest using data binding, this makes it easier to work with the ListBox. First make sure to override ToString in the Customer class to make is displayable in the ListBox
Public Class Customer
Public Property FirstName As String
Public Property LastName As String
Public Property Age As Integer
Public Property Email As String
Public Overrides Function ToString() As String
Return $"{FirstName} {LastName} ({Age}) {Email}"
End Function
End Class
Then we use a List(Of Customer) instead of an ArrayList. The advantage is that the List(Of ) is strongly typed, i.e., its elements are of type Customer, where as the ArrayList has elements of type Object.
Also, we create a wrapper of type BindingList(Of Customer) to wrap our list to enable auto-updating of the ListBox. Example:
Public Class Form1
Dim customers As New List(Of Customer)
Dim customersBinding As BindingList(Of Customer)
Public Sub New()
InitializeComponent()
customersBinding = New BindingList(Of Customer)(customers)
lstCustomer.DataSource = customersBinding
End Sub
Private Sub NewCustomer(ByVal fn As String, ByVal ln As String, ByVal a As Integer, ByVal e As String)
Dim customer As New Customer With {
.FirstName = fn,
.LastName = ln,
.Age = a,
.Email = e
}
customersBinding.Add(customer)
lstCustomer.SelectedItem = customers(customers.Count - 1)
' or lstCustomer.SelectedIndex = customers.Count - 1
End Sub
Private Sub BtnTest_Click(sender As Object, e As EventArgs) Handles BtnTest.Click
NewCustomer("Homer", "Simpson", 40, "HSimpson#springf.com")
NewCustomer("Bruce", "Banner", 44, "green#giant.com")
End Sub
Public Sub DisplayCustomer(ByVal customer As Customer)
TxtFirstName.Text = customer.FirstName
TxtLastName.Text = customer.LastName
TxtAge.Text = customer.Age.ToString()
TxtEmail.Text = customer.Email
End Sub
Private Sub lstCustomer_SelectedIndexChanged(sender As Object, e As EventArgs) Handles lstCustomer.SelectedIndexChanged
Dim index As Integer = lstCustomer.SelectedIndex
If index >= 0 Then
DisplayCustomer(customers(index))
End If
End Sub
Private Sub btnAdd_Click(sender As Object, e As EventArgs) Handles btnAdd.Click
NewCustomer(TxtFirstName.Text, TxtLastName.Text, CInt(TxtAge.Text), TxtEmail.Text)
End Sub
End Class
In the constructor we create the binding list and set it as data source of the ListBox.
See how Sub NewCustomer only adds the new customer to the binding list. This inserts the customer to the wrapped list as well and at the same time updates the ListBox.
We also automatically select the last inserted customer in the ListBox with
lstCustomer.SelectedItem = customers(customers.Count - 1)
or (easier)
lstCustomer.SelectedIndex = customers.Count - 1
We use the SelectedIndexChanged event to automatically display the customer in the textboxes when the user selects another customer in the listbox.
You could also extend data binding to automatically bind the customer objects to the textboxes. You will find a lot of online tutorials on this subject.