In VBA, How can I trim any characters not just whitespaces? - vba

Question

Due to some other sloppy coding, I need to remove leading or trailing vbCrLf or reduce any instances of more than one consecutive vbCrLf to a single line.
So how can I execute the trim function, but to trim a character other than " " ?

Answer 1

Here are functions to do just that
Function TrimAny(ByVal myString As String, myTrim As String) As String
If myString = "" Or myTrim = "" Then TrimAny = myString: Exit Function
While inStB(myString, myTrim & myTrim): myString = Replace(myString, myTrim & myTrim, myTrim): Wend
myString = TrimStart(myString, myTrim)
myString = TrimEnd(myString, myTrim)
TrimAny = myString
End Function
Function TrimEnd(ByVal myString As String, myTrim As String) As String
If myString = "" Or myTrim = "" Then TrimEnd = myString: Exit Function
While Right(myString, Len(myTrim)) = myTrim: myString = Left(myString, Len(myString) - Len(myTrim)): Wend
TrimEnd = myString
End Function
Function TrimStart(ByVal myString As String, myTrim As String) As String
If myString = "" Or myTrim = "" Then TrimStart = myString: Exit Function
While Left(myString, Len(myTrim)) = myTrim: myString = Right(myString, Len(myString) - Len(myTrim)): Wend
TrimStart = myString
End Function

Answer 2

Solution with RegExp:
Function CrLfTrim(ByVal text As String) As String
' set a reference to 'Microsoft VBScript Regular Expression 5.5' in Tools->References VBE menu
Static re As RegExp ' re is Static and stores the object between function calls, so there is no need to create it each time
If re Is Nothing Then ' it is only necessary to create re if it is Nothing (first time)
Set re = New RegExp
re.Global = True
End If
With re
.Pattern = "(^(\x0D\x0A)+)|((\x0D\x0A)+$)" 'set pattern to remove leading and trailing vbCrLf
text = .Replace(text, "") 'remove leading and trailing vbCrLf
.Pattern = "(\x0D\x0A){2,}" 'set the pattern for the internal sequential vbCrLf
CrLfTrim = .Replace(text, vbCrLf) ' replace the internal sequential vbCrLf with one vbCrLf
End With
End Function
Usage example:
Sub Example()
Dim txt As String: txt = vbCrLf & "Lorem ipsum dolor sit " & vbCrLf & vbCrLf & vbCrLf & "amet, consectetur " & vbCrLf & vbCrLf
Debug.Print "Before: [" & txt & "]"
Debug.Print "After: [" & CrLfTrim(txt) & "]"
End Sub
Prints:
Before: [
Lorem ipsum dolor sit
amet, consectetur
]
After: [Lorem ipsum dolor sit
amet, consectetur ]