Why are my database Commands always calling sp_describe_first_result_set? - vb.net

Question

Background
I'm maintaining a VB.Net (formerly VB6) utility that exports records to a flat file. One of our customers reported that the new version was taking a long time to run, and digging into the trace it was easy to see why: (I've obfuscated this slightly)
exec [sys].sp_describe_first_result_set
N'Update [MAIN].[dbo].[Inventory] Set ExportId = #P1 Where Comp = #P2 and Osite = #P3 and Key = #P4',
N'#P1 numeric(10),#P2 varchar(6),#P3 varchar(6),#P4 int',1
This and statements like it were taking half a second each. The utility has to update the main inventory table with some information about the export, and the table is heavily triggered, so sp_describe_first_result_set has to simulate all the triggers in order to determine the result - I can verify that later down in the trace.
Problem
I can't figure out why exactly my code is calling sp_describe_first_result_set for an update statement, a thing that doesn't even have a result set. The command setup doesn't look like it's doing anything weird:
Dim connection = New ADODB.Connection
connection.ConnectionString = config.AdoConnectionString
connection.CursorLocation = CursorLocationEnum.adUseClient
connection.Open()
cmd = New ADODB.Command
With cmd
.ActiveConnection = connection
.CommandType = CommandTypeEnum.adCmdText
.CommandText = "Update [MAIN].[dbo].[Inventory] " &
"Set ExportId = ? " &
"Where Comp = ? and Osite = ? and Key = ?"
.Parameters.Append(NumericParameter(cmd.CreateParameter("ExportId", DataTypeEnum.adNumeric, ParameterDirectionEnum.adParamInput), 10, 0))
.Parameters.Append(cmd.CreateParameter("Comp", DataTypeEnum.adVarChar, ParameterDirectionEnum.adParamInput, 6))
.Parameters.Append(cmd.CreateParameter("Osite", DataTypeEnum.adVarChar, ParameterDirectionEnum.adParamInput, 6))
.Parameters.Append(cmd.CreateParameter("Key", DataTypeEnum.adInteger, ParameterDirectionEnum.adParamInput))
End With
cmd.Parameters("ExportID").Value = lExportId
cmd.Parameters("Comp").Value = sComp
cmd.Parameters("Osite").Value = sOsite
cmd.Parameters("Key").Value = iKey
cmd.Execute()
Is there some setting I'm just missing that's making it run sp_describe_first_result_set all the time? Is there a way to stop it from doing that?

Answer 1

You need to explicitly say you don't want a recordset.
In VB6, an ADODB Command object can tell whether or not it should return a recordset based on whether the value of the Execute() function is being assigned to anything.
In VB.NET, this is no longer done, but execution options flags can be provided as arguments to the Execute() function. Calling the command like this:
cmd.Parameters("ExportID").Value = lExportId
cmd.Parameters("Comp").Value = sComp
cmd.Parameters("Osite").Value = sOsite
cmd.Parameters("Key").Value = iKey
cmd.Execute(Options:=ExecuteOptionEnum.adExecuteNoRecords)
will not call sp_describe_first_result_set to establish the parameters of the record set, but will only execute the command directly, the same way more modern methods such as SqlCommand.ExecuteNonQuery() will.

Answer 2

Out of curiosity, does the modern equivalent to that code also trace as performing this op?
Dim cmd as New SqlCommand( _
"Update [MAIN].[dbo].[Inventory] Set ExportId = #e Where Comp = #c and Osite = #o and Key = #k",
"Data Source=YOUR_SERVER;Initial Catalog=YOUR_DB;User ID=YOUR_USER_EG_sa;Password=YOUR_PASSWORD" _
)
cmd.Connection.Open()
cmd.Parameters.AddWithValue("#e", lExportId)
cmd.Parameters.AddWithValue("#c", sComp)
cmd.Parameters.AddWithValue("#o", sOsite)
cmd.Parameters.AddWithValue("#k", iKey)
cmd.ExecuteNonQuery()
I use AddWithValue for testing/convenience purposes here, but you should probably avoid it in prod because it can cause performance issues with SQLS - see that link for advice on how to craft parameters properly