Replacing Comma character with Serial No - vba

Question

In place of
Comma space Anil, Comma space Sunil etc
as illustrated below:
, Anil, Sunil etc
.
I want to Give Serial No in Same Line like:
(1) Anil (2) Sunil etc
'The Procedure has to do a lot of unnecessary work. Is there a better way.
'Put Curser anywhere befor first Comma
Sub GiveSerialToLinerPoints()
x = ActiveDocument.Range(0, Selection.Paragraphs(1). _
Range.End).Paragraphs.Count
i = 0
For Each char In ActiveDocument.Paragraphs(x).Range.Characters
If char = "," Then
i = i + 1
End If
Next char
TotalCommas = i
For i = 1 To TotalCommas
With Selection
.StartIsActive = False
.Extend Character:=","
.Collapse Direction:=wdCollapseEnd
.MoveLeft
.Expand Unit:=wdCharacter
If .Text = "," Then
.Text = " (" & i & ")"
End If
End With
Next i
End Sub

Answer 1

Try:
Sub Demo()
Application.ScreenUpdating = False
Dim i As Long
With ActiveDocument.Range
With .Find
.ClearFormatting
.Replacement.ClearFormatting
.Text = ","
.Replacement.Text = ""
.Forward = True
.Wrap = wdFindStop
.Format = False
.MatchCase = False
.MatchWholeWord = False
.MatchWildcards = False
.MatchSoundsLike = False
.MatchAllWordForms = False
End With
Do While .Find.Execute
i = i + 1
.Text = "(" & i & ")"
.Collapse wdCollapseEnd
Loop
End With
Application.ScreenUpdating = True
MsgBox i & " commas replaced."
End Sub
To limit the F/R to just the paragraph the insertion point is in, you could use:
Sub Demo()
Application.ScreenUpdating = False
Dim Rng As Range, i As Long
With Selection.Paragraphs.First
Set Rng = .Range
With .Range
With .Find
.ClearFormatting
.Replacement.ClearFormatting
.Text = ","
.Replacement.Text = ""
.Forward = True
.Wrap = wdFindStop
.Format = False
.MatchCase = False
.MatchWholeWord = False
.MatchWildcards = False
.MatchSoundsLike = False
.MatchAllWordForms = False
End With
Do While .Find.Execute
If .InRange(Rng) Then
i = i + 1
.Text = "(" & i & ")"
Else
Exit Do
End If
.Collapse wdCollapseEnd
Loop
End With
End With
Application.ScreenUpdating = True
MsgBox i & " instances found."
End Sub

Answer 2

For the output, once the string is captured from your document, you could use Split() to split the string with the comma as delimiter, then via the loop build the new result string.
Something like:
Sub foo()
Dim StartString As String
Dim ResultString As String
Dim TempSplit As Variant
Dim LoopCounter As Long
StartString = "Anil, Sunil"
TempSplit = Split(MyString, ",")
For LoopCounter = 1 To UBound(TempSplit) + 1
ResultString = ResultString & TempSplit(LoopCounter - 1) & "(" & LoopCounter & ")"
Next LoopCounter
Debug.Print ResultString
End Sub
This starts with the string:
"Anil, Sunil"
And prints to the immidiate window:
(1)Anil (2)Sunil

Answer 3

One alternative is to count backwards over the Characters :
Sub GiveSerialToLinerPoints()
Dim i As Long, rng As Range, n As Long
Set rng = Selection.Paragraphs(1).Range
n = 1 + Len(rng.Text) - Len(Replace(rng.Text, ",", "")) '# of commas plus one
For i = rng.Characters.Count To 1 Step -1
If rng.Characters(i).Text = "," Then
rng.Characters(i).Text = " (" & n & ")"
n = n - 1
End If
Next i
rng.Characters(1) = "(1) " & rng.Characters(1).Text
End Sub

Answer 4

'Site:my account in StackOverflow
'By Samual Everson
' in place of Comma space Anil Sharaf Comma space Sunil Sharaf Like
', Anil Sharaf, Sunil Sharaf, etc. How to Give Serial No in Same Line Like:
'(1) Anil Sharaf (2) Sunil Sharaf etc
'Select the Comma delemited Words.
'then Run this macro by F5
Sub GiveSerialToCommaDelimitedWordsSelectMethod_Quick()
Dim StartString As String
Dim ResultString As String
Dim TempSplit As Variant
Dim LoopCounter As Long
If Selection.Type = wdSelectionIP Then
MsgBox "You need to select the Comma Delimited Words."
Exit Sub
End If
StartString = Selection.Text
TempSplit = Split(StartString, ",")
For LoopCounter = 1 To UBound(TempSplit)
ResultString = ResultString & "(" & LoopCounter & ")" & TempSplit(LoopCounter) & " "
Next LoopCounter
Selection.Text = ResultString
End Sub