Ignore, or avoid circular reference in UDF? - vba

Question

I am trying to make a planner. I have a table which I want to be something like this:
ID
Parent ID
Start Date
Duration
End Date
1
01/01/2021
10
11/01/2021
2
1
06/05/2021
2
08/05/2021
3
2
08/05/2021
1
09/05/2021
4
3
09/05/2021
5
14/05/2021
5
2,3,4
14/05/2021
4
18/05/2021
The Start date will be based on matching the Parent ID to the Task ID, so task 2 follows task 1, task 2 follows task 3 etc. I also want to be able to test against multiple tasks that might be happening at the same time, so task 5 can start after tasks 2, 3 or 4, which ever ends last.
I wrote this UDF for the start date calculation.
Option Explicit
Function LastPredecessor(PreList As String, TaskList As Range, TaskDueDate As Range)
Dim ID
Dim Dates
Dim nPres, i As Integer
On Error Resume Next
Pres = Split(PreList, ",")
nPres = UBound(Pres)
ReDim Dates(0 To nPres, 0)
For i = 0 To nPres
Dates(i, 0) = IDX_Match(CInt(Pres(i)), TaskList, TaskDueDate)
Next
LastPredecessor = WorksheetFunction.Max(Dates)
End Function
Function IDX_Match(LookupVal, MatchRange As Range, LookupRange As Range, Optional MatchType As Integer = 0)
IDX_Match = WorksheetFunction.Index(LookupRange.Value2, WorksheetFunction.Match(LookupVal, MatchRange.Value2, MatchType))
End Function
The function is called in the start date in the table like this
=LastPredecessor([#Parent ID],[ID],[End Date])
It works well if the end date is independent of the start date, but as soon as I try to update the end date, and add start date + duration as the calculation for end date, it generates a circular error.
I am sure I am doing something very simple wrong, but would be great to know what I need to do to fix this.
EDIT:
Thanks to #Toddleson, the following is a slightly modified version
Function LastPredecessor(PreList As String, EndDates As Range, IDColumn As Range) As Date
Dim Preds() As String, PredDates() As Long
Preds = Split(PreList, ",")
ReDim PredDates(UBound(Preds))
For i = LBound(Preds) To UBound(Preds)
PredDates(i) = IDColumn(WorksheetFunction.Match(CInt(Preds(i)), IDColumn, 0)).Offset(0, EndDates.Column - IDColumn.Column).Value2
Next i
LastPredecessor = Application.WorksheetFunction.Max(PredDates)
End Function

Answer 1

Ok, I rewrote the function. It should be doing exactly what you described to me.
Function LastPredecessorV2(PreList As String, EndDates As Range, IDColumn As Range) As Date
Dim Preds() As String, PredDates() As Long
Preds = Split(Replace(PreList, " ", ""), ",")
ReDim PredDates(UBound(Preds))
For i = LBound(Preds) To UBound(Preds)
PredDates(i) = IDColumn.Find( _
What:=CInt(Preds(i)), _
LookAt:=xlWhole _
).Offset(0, EndDates.Column - IDColumn.Column).Value2 'Corrected
Next i
LastPredecessorV2 = CDate(Application.WorksheetFunction.Max(PredDates))
End Function
Here's how the input of the arguments looks. Those ranges can be the entire column and it still works.
All of the End Dates are using the formula (Start Date + Duration in Days). The first task start date is the only independent value in the column, all the other ones are using the formula.
Edit:
I should mention that you can insert columns in-between the ranges and the function will still work.