Combine three text files - vb.net

Question

How does one combine three text files together into one? I was also trying to make it alphabetical by state in the new text file. I figured how to combine two but three I am getting lost.
Public Class newsenatefrm
Dim current() As String = IO.File.ReadAllLines("Senate113.txt")
Dim retired() As String = IO.File.ReadAllLines("RetiredSen.txt")
Dim newSen() As String = IO.File.ReadAllLines("NewSen.txt")
Dim queryCurrent = From line In current
Let state = Split(","c)(1)
Let name = Split(","c)(0)
Let party = Split(","c)(2)
Order By state Ascending
Select state, name, party
Dim queryRetired = From line In retired
Let state = Split(","c)(1)
Let name = Split(","c)(0)
Let party = Split(","c)(2)
Order By state Ascending
Select state, name, party
Dim queryNew = From line In newSen
Let state = Split(","c)(1)
Let name = Split(","c)(0)
Let party = Split(","c)(2)
Order By state Ascending
Select state, name, party
Private Sub generatebtn_Click(sender As Object, e As EventArgs) Handles generatebtn.Click
IO.File.WriteAllText("Senate114.txt")
End Sub
End Class
I included sample text from the three text files below:
Senate113.txt:
Richard Shelby,Alabama,R
Bernard Sanders,Vermont,I
Kristen Gillibrand,New York,D
Retired.txt:
John Rockefeller,West Virginia,D
Tom Coburn,Oklahoma,R
Carl Levin,Michigan,D
NewSen.txt:
Shelly Capito,West Virginia,R
Steve Daines,Montana,R
Gary Peters,Michigan,D

Answer 1

As you're just learning Visual Basic, you might enjoy finding some new things in this answer.
You've got files with the data separated by commas, a common format known as a comma-separated values file, or CSV file. There are several parsers available for that format, I'm just using the TextFieldParser Class because it comes with VB.NET.
If you're going to be working with data, it is very often a good idea to make a class for the data items - it allows you to keep associated data together, with sensible names, and provide methods that work with that data.
So, you could have one main List(Of Senator) to which you can add more data (senators) from a file, perhaps like this:
Imports System.IO
Imports Microsoft.VisualBasic.FileIO
Module Module1
Public Class Senator
Property Name As String
Property State As String
Property Party As String
Public Sub New()
' Empty constructor
End Sub
Public Sub New(name As String, state As String, party As String)
Me.Name = name
Me.State = state
Me.Party = party
End Sub
Public Overrides Function ToString() As String
Return $"{Name}, {State}, {Party}"
End Function
End Class
Function GetSenators(fromFile As String) As List(Of Senator)
Dim s As New List(Of Senator)
Using csvReader As New TextFieldParser(fromFile)
csvReader.Delimiters = {","}
While Not csvReader.EndOfData
Dim parts = csvReader.ReadFields()
If parts.Count = 3 Then
s.Add(New Senator(parts(0), parts(1), parts(2)))
End If
End While
End Using
Return s
End Function
Sub Main()
Dim srcDir = "C:\temp"
Dim srcFiles = {"Senate113.txt", "RetiredSen.txt", "NewSen.txt"}
Dim combinedSenators As New List(Of Senator)
For Each f In srcFiles
Dim actualFile = Path.Combine(srcDir, f)
combinedSenators.AddRange(GetSenators(actualFile))
Next
Dim senatorsByState = combinedSenators.OrderBy(Function(sen) sen.State).Select(Function(s) s.ToString())
Console.WriteLine(String.Join(vbCrLf, senatorsByState))
'File.WriteAllLines("C:\temp\Senate114.txt", senatorsByState)
Console.Write("Finished.")
Console.ReadLine()
End Sub
End Module
Which, with the sample data in the question, outputs:
Richard Shelby, Alabama, R
Carl Levin, Michigan, D
Gary Peters, Michigan, D
Steve Daines, Montana, R
Kristen Gillibrand, New York, D
Tom Coburn, Oklahoma, R
Bernard Sanders, Vermont, I
John Rockefeller, West Virginia, D
Shelly Capito, West Virginia, R

Answer 2

There are many possible ways, but as it looks like the files you're dealing with will be quite small, you could read them all into a List(Of String) to start with:
Dim a = IO.File.ReadLines("C:\temp\Senate113.txt").ToList()
a.AddRange(IO.File.ReadLines("C:\temp\RetiredSen.txt"))
a.AddRange(IO.File.ReadLines("C:\temp\NewSen.txt"))
Then carry on as you did before, you just need to do it once instead of thrice.
(It's best to give a full path to a file.)