Setting up a 60 minute timer with pause function - vb.net

Question

thanks in advance for any help you can give.
I am trying to set up a 60 minute timer and so far that was the easy part:
Dim Breaktime As Date
Sub Timer2Tick(sender As Object, e As EventArgs)
Dim Breaktimer As TimeSpan = breaktime - DateTime.Now.AddSeconds(-1)
Breaklabel.Text = breaktimer.Minutes.ToString("00") & ":" & breaktimer.Seconds.ToString("00")
If Breaklabel.Text = "00:00" Then
Timer1.Stop()
MsgBox("Time Over")
End If
End Sub
My start button is just a simple start function
Timer2.Start()
button1.Visible = False
button2.Visible = true
then I have a stop button that stops the timer and makes the start button visible.
Timer2.STOP()
button2.Visible = False
button1.Visible = true
the issue I am having is that the timer is based on Datetime which means when I resume it, it resumes the timer based on the system clock.
What I am trying to do is set up a 60 minute timer in the MM:SS format that is not based on Datetime but for the life of me I cannot get the system to translate 3600 seconds into the MM:SS format and count down the same way as the DateTime does.
Any ideas.

Answer 1

This is the bones of what you need to do:
Private countdownStopwatch As New Stopwatch
Private timePeriod As TimeSpan = TimeSpan.FromMinutes(60)
Private Sub StartStop(Optional resetElapsedTime As Boolean = True)
If countdownStopwatch.IsRunning Then
'Stop the Stopwatch and the Timer.
countdownStopwatch.Stop()
Timer1.Stop()
If resetElapsedTime Then
'Reset the elapsed time period.
countdownStopwatch.Reset()
End If
DisplayTimeRemaining()
Else
'Start the Stopwatch and the Timer.
If resetElapsedTime Then
'Reset the elapsed time period.
countdownStopwatch = Stopwatch.StartNew()
Else
countdownStopwatch.Start()
End If
DisplayTimeRemaining()
Timer1.Start()
End If
End Sub
Private Sub PauseResume()
'Start or stop timing without resetting the elapsed time.
StartStop(False)
End Sub
Private Sub DisplayTimeRemaining()
Dim timeRemaining = timePeriod - countdownStopwatch.Elapsed
If timeRemaining < TimeSpan.Zero Then
timeRemaining = TimeSpan.Zero
End If
Label1.Text = timeRemaining.ToString("mm\:ss")
End Sub
Private Sub Timer1_Tick(sender As Object, e As EventArgs) Handles Timer1.Tick
If countdownStopwatch.Elapsed >= timePeriod Then
StartStop()
Else
DisplayTimeRemaining()
End If
End Sub
I'll leave it to you to decide when to enable and disable which Buttons and the like.