Visual Basic - start stopwatch for measuring overtime after a given amount of minutes - vb.net

Question

I'm starting my first steps into Visual Basic and trying to create sort of a stopwatch.
My design is the following:
The idea behind is to create a tool to support a debate. Persons gets a certain time (7 minutes) for presenting their topic and after that time there is room for interactive conversation (Q&A) set to 13 minutes. The idea is that after 7 minutes a buzzer sounds to stop the presenting time and go over to the interactive part. And after 20 minutes a 2nd stopwatch starts with a buzzer and a red flashing background to indicate that session needs to be terminated.
This is what I already got and I'm pretty shure it can be coded otherwise and maybe easier.
I already got it to the first working stopwatch but I don't get the rest working:
Public Class Form1
Private Hundredths As Integer = 0
Private Seconds As Integer = 0
Private Minutes As Integer = 0
Private Hours As Integer = 0
Private OvertimeHundredths As Integer = 0
Private OvertimeSeconds As Integer = 0
Private OvertimeMinutes As Integer = 0
Private OvertimeHours As Integer = 0
Private Sub StartBtn_Click(sender As Object, e As EventArgs) Handles StartBtn.Click
If Timer1.Enabled Then
Timer1.Stop()
StartBtn.Text = "START"
Return
End If
If Not Timer1.Enabled Then
Timer1.Start()
StartBtn.Text = "STOP"
Return
End If
End Sub
Private Sub Timer1_Tick(sender As Object, e As EventArgs) Handles Timer1.Tick
Hundredths += 1
HundredthsTxB.Text = Hundredths.ToString
SecondsTxB.Text = Seconds.ToString
MinutesTxB.Text = Minutes.ToString
HoursTxB.Text = Hours.ToString
If Hundredths = 10 Then
Seconds += 1
Hundredths = 0
End If
If Seconds = 60 Then
Minutes += 1
Seconds = 0
End If
If Minutes = 60 Then
Hours += 1
Minutes = 0
End If
If Hours = 24 Then
Timer1.Stop()
End If
End Sub
Private Sub ResetBtn_Click(sender As Object, e As EventArgs) Handles ResetBtn.Click
Hundredths = 0
Seconds = 0
Minutes = 0
Hours = 0
HundredthsTxB.Text = Hundredths.ToString
SecondsTxB.Text = Seconds.ToString
MinutesTxB.Text = Minutes.ToString
HoursTxB.Text = Hours.ToString
End Sub
Private Sub Timer2_Tick(sender As Object, e As EventArgs) Handles Timer2.Tick
OvertimeHundredths += 1
OvertimeHundredthsTxB.Text = OvertimeHundredths.ToString
OvertimeSecondsTxB.Text = OvertimeSeconds.ToString
OvertimeMinutesTxB.Text = OvertimeMinutes.ToString
OvertimeHoursTxB.Text = OvertimeHours.ToString
If OvertimeHundredths = 10 Then
OvertimeSeconds += 1
OvertimeHundredths = 0
End If
If OvertimeSeconds = 60 Then
OvertimeMinutes += 1
OvertimeSeconds = 0
End If
If OvertimeMinutes = 60 Then
OvertimeHours += 1
OvertimeMinutes = 0
End If
If OvertimeHours = 24 Then
Timer2.Stop()
End If
End Sub
Private Sub Form1_Load(sender As Object, e As EventArgs) Handles MyBase.Load
If Timer1.Interval = 2 Then
Timer2.Start()
End If
End Sub
End Class
So any help is welcome. Also I'm keen on learning on how other guru's are thinking and coding.

Answer 1

Instead of using timers, I would use a Stopwatch. This way there is less messing around adding numbers etc. The code below accomplishes what you want apart from sounding a buzzer as I'm presuming you want to implement it your own. It looks worse than it is, but seems to work ok. See code comments for a little explanation
Public Class Form1
Private PresentationTimer As New Stopwatch
Private InteractiveTimer As New Stopwatch
Private PresentationMinutes As Integer
Private InteractiveMinutes As Integer
'When this timer is enabled, it keeps track of the two stopwatches and checks
'that they're within the alloted time.
'
'When the presentation timer has expired, that one is stopped and the interactive
'timer is started
'
'When the interactive timer has expired, the timer for background flashing starts.
'To stop the flashing, click the reset button on the form
Private Sub UiUpdateTimer_Tick(sender As Object, e As EventArgs) Handles uiUpdateTimer.Tick
UpdateUI()
If PresentationTimer.IsRunning And IsTimeExpired(PresentationTimer, PresentationMinutes) Then
PresentationTimer.Stop()
InteractiveTimer.Start()
'add code here for buzzer to show end of presentation time
End If
If InteractiveTimer.IsRunning And IsTimeExpired(InteractiveTimer, InteractiveMinutes) Then
InteractiveTimer.Stop()
BackgroundFlashTimer.Enabled = True
'add code here for buzzer to show end of interactive time
StartBtn.Text = "START"
End If
End Sub
'checks if the timer passed as a parameter is expired by comparing
'the number of elapsed minutes with the number of minutes passed in
'the second parameter
Private Function IsTimeExpired(tmr As Stopwatch, mins As Integer) As Boolean
If tmr.Elapsed.Minutes >= mins Then
Return True
Else
Return False
End If
End Function
'simply updates all the textboxes with the stopwatch values.
Private Sub UpdateUI()
HundredthsTxB.Text = Int(PresentationTimer.Elapsed.Milliseconds / 10).ToString
SecondsTxB.Text = PresentationTimer.Elapsed.Seconds.ToString
MinutesTxB.Text = PresentationTimer.Elapsed.Minutes.ToString
HoursTxB.Text = PresentationTimer.Elapsed.Hours.ToString
OvertimeHundredthsTxB.Text = Int(InteractiveTimer.Elapsed.Milliseconds / 10).ToString
OvertimeSecondsTxB.Text = InteractiveTimer.Elapsed.Seconds.ToString
OvertimeMinutesTxB.Text = InteractiveTimer.Elapsed.Minutes.ToString
overtimeHoursTxB.Text = InteractiveTimer.Elapsed.Hours.ToString
End Sub
Private Sub StartBtn_Click(sender As Object, e As EventArgs) Handles StartBtn.Click
'if either timer is running, stop them both and exit this sub
If PresentationTimer.IsRunning Or InteractiveTimer.IsRunning Then
PresentationTimer.Stop()
InteractiveTimer.Stop()
StartBtn.Text = "START"
uiUpdateTimer.Enabled = False
Exit Sub
End If
'if the presentation timer hasn't run yet, check if the minutes values are
'valid and start it
If PresentationTimer.ElapsedMilliseconds = 0 Then
PresentationMinutes = CInt(Val(PresentationMinutesTxB.Text))
InteractiveMinutes = CInt(Val(InteractiveMinutesTxB.Text))
'if the minutes values are't valid show messagebox and exit this sub
If PresentationMinutes = 0 Or InteractiveMinutes = 0 Then
MessageBox.Show("Please enter valid Presentation and Interactive times.")
Exit Sub
End If
'if minutes values are ok start the presentation timer
uiUpdateTimer.Enabled = True
PresentationTimer.Start()
StartBtn.Text = "STOP"
Exit Sub
End If
'if the presentation timer has been running, but is currently stopped,
'continue the timer and exit this sub
If Not PresentationTimer.IsRunning And PresentationTimer.ElapsedMilliseconds > 0 Then
uiUpdateTimer.Enabled = True
PresentationTimer.Start()
StartBtn.Text = "STOP"
Exit Sub
End If
'if the interactive timer has been running,but is currently stopped,
'continue the timer and exit this sub
If Not InteractiveTimer.IsRunning And InteractiveTimer.ElapsedMilliseconds > 0 Then
uiUpdateTimer.Enabled = True
InteractiveTimer.Start()
StartBtn.Text = "STOP"
Exit Sub
End If
End Sub
Private Sub ResetBtn_Click(sender As Object, e As EventArgs) Handles ResetBtn.Click
PresentationTimer.Reset()
InteractiveTimer.Reset()
uiUpdateTimer.Enabled = False
StartBtn.Enabled = True
StartBtn.Text = "START"
UpdateUI()
BackgroundFlashTimer.Enabled = False
Me.BackColor = defaultBackColor
End Sub
Private Sub BackgroundFlashTimer_Tick(sender As Object, e As EventArgs) Handles BackgroundFlashTimer.Tick
StartBtn.Enabled = False
If Me.BackColor = DefaultBackColor Then
Me.BackColor = Color.Red
Else
Me.BackColor = DefaultBackColor
End If
Me.Update()
End Sub
End Class

Answer 2

This was my final solution based on David Wilson's contribution:
Public Class Form1
Private PresentationTimer As New Stopwatch
Private InteractiveTimer As New Stopwatch
Private ExtraTimeTimer As New Stopwatch
Private PresentationMinutes As Integer
Private InteractiveMinutes As Integer
'When this timer is enabled, it keeps track of the two stopwatches and checks
'that they're within the alloted time.
'
'When the presentation timer has expired, that one is stopped and the interactive
'timer is started
'
'When the interactive timer has expired, the timer for background flashing starts.
'To stop the flashing, click the reset button on the form
Private Sub uiUpdateTimer_Tick(sender As Object, e As EventArgs) Handles uiUpdateTimer.Tick
UpdateUI()
If PresentationTimer.IsRunning And IsTimeExpired(PresentationTimer, PresentationMinutes) Then
PresentationTimer.Stop()
InteractiveTimer.Start()
Me.BackColor = Color.Yellow
'add code here for buzzer to show end of presentation time
End If
If InteractiveTimer.IsRunning And IsTimeExpired(InteractiveTimer, InteractiveMinutes) Then
InteractiveTimer.Stop()
BackgroundFlashTimer.Enabled = True
ExtraTimeTimer.Start()
'add code here for buzzer to show end of interactive time
StartBtn.Text = "START"
End If
End Sub
'checks if the timer passed as a parameter is expired by comparing
'the number of elapsed minutes with the number of minutes passed in
'the second parameter
Private Function IsTimeExpired(tmr As Stopwatch, mins As Integer) As Boolean
If tmr.Elapsed.Minutes >= mins Then
Return True
Else
Return False
End If
End Function
'simply updates all the textboxes with the stopwatch values.
Private Sub UpdateUI()
HundredthsTxB.Text = Int(PresentationTimer.Elapsed.Milliseconds / 10).ToString
SecondsTxB.Text = PresentationTimer.Elapsed.Seconds.ToString
MinutesTxB.Text = PresentationTimer.Elapsed.Minutes.ToString
HoursTxB.Text = PresentationTimer.Elapsed.Hours.ToString
OvertimeHundredthsTxB.Text = Int(InteractiveTimer.Elapsed.Milliseconds / 10).ToString
OvertimeSecondsTxB.Text = InteractiveTimer.Elapsed.Seconds.ToString
OvertimeMinutesTxB.Text = InteractiveTimer.Elapsed.Minutes.ToString
OvertimeHoursTxB.Text = InteractiveTimer.Elapsed.Hours.ToString
ExtraTimeHundredthsTxB.Text = Int(ExtraTimeTimer.Elapsed.Milliseconds / 10).ToString
ExtraTimeSecondsTxB.Text = ExtraTimeTimer.Elapsed.Seconds.ToString
ExtraTimeMinutesTxB.Text = ExtraTimeTimer.Elapsed.Minutes.ToString
ExtraTimeHoursTxB.Text = ExtraTimeTimer.Elapsed.Hours.ToString
End Sub
Private Sub StartBtn_Click(sender As Object, e As EventArgs) Handles StartBtn.Click
'if either timer is running, stop them both and exit this sub
If PresentationTimer.IsRunning Or InteractiveTimer.IsRunning Then
PresentationTimer.Stop()
InteractiveTimer.Stop()
ExtraTimeTimer.Stop()
StartBtn.Text = "START"
uiUpdateTimer.Enabled = False
Exit Sub
End If
'if the presentation timer hasn't run yet, check if the minutes values are
'valid and start it
If PresentationTimer.ElapsedMilliseconds = 0 Then
PresentationMinutes = CInt(Val(PresTimeTxB.Text))
InteractiveMinutes = CInt(Val(InterTimeTxB.Text))
'if the minutes values are't valid show messagebox and exit this sub
If PresentationMinutes = 0 Or InteractiveMinutes = 0 Then
MessageBox.Show("Please enter valid Presentation and Interactive times.")
Exit Sub
End If
'if minutes values are ok start the presentation timer
uiUpdateTimer.Enabled = True
PresentationTimer.Start()
StartBtn.Text = "STOP"
Exit Sub
End If
'if the presentation timer has been running, but is currently stopped,
'continue the timer and exit this sub
If Not PresentationTimer.IsRunning And PresentationTimer.ElapsedMilliseconds > 0 Then
uiUpdateTimer.Enabled = True
PresentationTimer.Start()
StartBtn.Text = "STOP"
Exit Sub
End If
'if the interactive timer has been running,but is currently stopped,
'continue the timer and exit this sub
If Not InteractiveTimer.IsRunning And InteractiveTimer.ElapsedMilliseconds > 0 Then
uiUpdateTimer.Enabled = True
InteractiveTimer.Start()
StartBtn.Text = "STOP"
Exit Sub
End If
End Sub
Private Sub ResetBtn_Click(sender As Object, e As EventArgs) Handles ResetBtn.Click
PresentationTimer.Reset()
InteractiveTimer.Reset()
ExtraTimeTimer.Reset()
uiUpdateTimer.Enabled = False
StartBtn.Enabled = True
StartBtn.Text = "START"
UpdateUI()
BackgroundFlashTimer.Enabled = False
Me.BackColor = DefaultBackColor
End Sub
Private Sub BackgroundFlashTimer_Tick(sender As Object, e As EventArgs) Handles BackgroundFlashTimer.Tick
StartBtn.Enabled = False
If Me.BackColor = DefaultBackColor Then
Me.BackColor = Color.Red
Else
Me.BackColor = DefaultBackColor
End If
Me.Update()
End Sub