Macro for Loop through outlook unread emails - vba

Question

I am trying adapt this code for use the macro only in unread emails in my Inbox, but I don’t get anything that works. Someone for helping me? THanks in advance.
Public Sub Unread_eMails()
Dim myNameSpace As Outlook.NameSpace
Dim myInbox As Outlook.Folder
Dim myDestFolder As Outlook.Folder
Set myNameSpace = Application.GetNamespace("MAPI")
Set myInbox = myNameSpace.GetDefaultFolder(olFolderInbox)
Set myDestFolder = myInbox.Folders("CHECK")
'For Each MyItem In myInbox
For Each MyItem In Application.ActiveExplorer.**¿?** 'I don't know what type here...
If myInbox.UnReadItemCount <> 0 Then
If InStr(MyItem.Body, "alarm") > 0 Then
MyItem.Move myDestFolder
Else
If InStr(MyItem.Subject, "Urgent") > 0 Then
MyItem.Move myDestFolder
Else
If InStr(MyItem.Body, "Closed") > 0 Then
MyItem.Categories = "Closed"
MyItem.Save
End If
End If
End If
MyItem.UnRead = False
End If
Next MyItem
End Sub

Answer 1

Limit the items to those that are unread with Restrict.
Loop in reverse when moving or deleting.
Option Explicit ' Consider this mandatory
' Tools | Options | Editor tab
' Require Variable Declaration
' If desperate declare as Variant
Public Sub Unread_eMails()
Dim myInbox As folder
Dim myDestFolder As folder
Dim myItem As Object
Dim myItems As Items
Dim myRestrictedItems As Items
Dim i As Long
Set myInbox = Session.GetDefaultFolder(olFolderInbox)
Set myDestFolder = myInbox.Folders("CHECK")
If myInbox.UnReadItemCount <> 0 Then
Set myItems = myInbox.Items
' Restrict to unread items
Set myRestrictedItems = myItems.Restrict("[UnRead] = True")
' Reverse loop when moving or deleting
For i = myRestrictedItems.Count To 1 Step -1
Set myItem = myRestrictedItems(i)
' Note: InStr is case sensitive
If InStr(myItem.body, "alarm") > 0 Then
myItem.Move myDestFolder
ElseIf InStr(myItem.subject, "Urgent") > 0 Then
myItem.Move myDestFolder
ElseIf InStr(myItem.body, "Closed") > 0 Then
myItem.categories = "Closed" ' save required
myItem.Save
myItem.UnRead = False ' save not required
End If
Next
End If
End Sub