Transposing Copy VBA - vba

Question

For example, my spreadsheet is just a like a [21x4] array.
Now I want to separate and arrange (copy & paste) three [7x4] arrays vertically from the abovementioned array to get a [7 x 12] array.
Any help would be highly appreciated. Thank you!

Answer 1

Try the next code, please. I hope I understood what you meant in your question...
Supposing that you followed the normal convention to expres the array in terms of rows followed by columns:
Sub sliceArrayTransposeHoriz()
Dim sh As Worksheet, arr, slice, nrRows As Long
Dim col As Long, lastRow As Long, i As Long
Set sh = ActiveSheet
nrRows = 7: col = 4: lastRow = 21
arr = sh.Range("A1:D" & lastRow).Value 'put the range in an array
For i = nrRows + 1 To lastRow Step nrRows
'take an array slice of 7 rows and 4 columns:
slice = Application.Index(arr, Application.Evaluate("row(" & i & ":" & _
i + nrRows - 1 & ")"), Array(1, 2, 3, 4))
'drop the slice content in the next empty column:
sh.cells(col + 1).Resize(UBound(slice), UBound(slice, 2)).Value = slice
col = col + 4 'obtain the next last column for the following slice content dropping
Next
'clear the range starting from the 8th row:
sh.Range(sh.cells(nrRows + 1, 1), sh.cells(lastRow, 4)).ClearContents
End Sub
But, since your question is not clear, at least for me, please also test the code version of vertically transposing:
Sub sliceArrayTransposeVert()
Dim sh As Worksheet, arr, slice, nrRows As Long
Dim cols As Long, lastRow As Long, lastCol As Long, i As Long
Set sh = ActiveSheet
nrRows = 7: cols = 4
lastCol = sh.cells(1, Columns.count).End(xlToLeft).Column
arr = sh.Range("A1:L7").Value
For i = cols + 1 To lastCol Step cols
slice = Application.Index(arr, Application.Evaluate("row(1:7)"), _
Application.Transpose(Application.Evaluate("row(" & i & ":" & i + cols - 1 & ")")))
sh.cells(nrRows + 1, 1).Resize(UBound(slice), UBound(slice, 2)).Value = slice ': Stop
nrRows = nrRows + 7
Next
sh.Range(sh.cells(1, cols + 1), sh.cells(7, lastCol)).ClearContents
End Sub

Answer 2

Put the following code in a module:
Public Sub SpreadBlocks(ByRef r_src As Range, ByVal n_rows As Long, ByRef r_dst As Range)
Dim n_all_rows As Long, n_cols As Long
n_all_rows = r_src.Worksheet.Range( _
r_src, r_src.End(xlDown)).Rows.Count
n_cols = r_src.Worksheet.Range( _
r_src, r_src.End(xlToRight)).Columns.Count
Dim n_blocks As Long, i As Long
n_blocks = n_all_rows \ n_rows
For i = 1 To n_blocks
r_dst.Offset(0, (i - 1) * n_cols).Resize(n_rows, n_cols).Value2 = _
r_src.Offset((i - 1) * n_rows, 0).Resize(n_rows, n_cols).Value2
Next i
End Sub
To be called as follows:
Public Sub Test()
SpreadBlocks Range("A2"), 7, Range("F2")
' | | |
' | | +-> Top left cell of destination
' | +----> Number of rows for each block
' +-----------------> Top left cell of source
End Sub