How to manipulate clipboard string using before pasting it? - vba

Question

I'm trying to write two VBA codes.
The first one is to add parentheses around the quotes text and remove line breaks and paragraph breaks.
The copied text always has a line break and then paragraph break near the end.
I would like to remove this, add in two double spaced, and put parentheses at the start of the text and right before where the line break was, and add a period at the end and then paste it.
An example would be:
A mandamus is the proper remedy[line break][paragraph break] Marburg v. Madison, 5 U.S. 137, 139 (1803)
Pasted To:
"A mandamus is the proper remedy." Marburg v. Madison, 5 U.S. 137, 139 (1803).
My second code would do the same thing, but flip it and add parentheses as well.
The finished product would like like:
Marburg v. Madison, 5 U.S. 137, 139 (1803) ("A mandamus is the proper remedy.").
How do I manipulate a string on the clipboard like this.
Sub Test()
Application.ScreenUpdating = False
Dim Rng As range
Set Rng = Selection.range
Rng.PasteAndFormat (wdFormatSurroundingFormattingWithEmphasis)
With Rng
.InsertBefore Chr(147)
.MoveStartUntil Chr(11), wdForward
.End = .Start + 2
.Text = Chr(148) & " "
End With
Selection.MoveStartUntil ")", wdForward
Application.ScreenUpdating = True
End Sub
For the Demoflipped, I tried
Rng.PasteAndFormat (wdFormatSurroundingFormattingWithEmphasis)

Answer 1

Try:
Sub DemoStraight()
Application.ScreenUpdating = False
Dim Rng As Range
Set Rng = Selection.Range
With Rng
.Paste
.Text = Chr(34) & Replace(.Text, Chr(11) & vbCr, Chr(34) & ". ")
End With
Application.ScreenUpdating = True
End Sub
and:
Sub DemoFlipped()
Application.ScreenUpdating = False
Dim Rng As Range, StrTmp As String
Set Rng = Selection.Range
With Rng
.Paste
StrTmp = Replace(.Text, Chr(11), "")
.Text = Split(StrTmp, vbCr)(1) & " (" & Chr(34) & Split(StrTmp, vbCr)(0) & Chr(34) & ".)"
End With
Application.ScreenUpdating = True
End Sub
Format retention requires a different approach. For example:
Sub DemoStraight()
Application.ScreenUpdating = False
Dim Rng As Range
Set Rng = Selection.Range
With Rng
.Paste
.InsertBefore Chr(34)
.MoveStartUntil Chr(11), wdForward
.End = .Start + 2
.Text = Chr(34) & ". "
End With
Application.ScreenUpdating = True
End Sub
and:
Sub DemoFlipped()
Application.ScreenUpdating = False
Dim RngA As Range, RngB As Range, StrTmp As String
Set RngA = Selection.Range
With RngA
.Paste
Do While .Characters.Last Like "[ " & Chr(11) & vbCr & "]"
.End = .End - 1
Loop
.InsertBefore " (" & Chr(34)
Set RngB = .Duplicate
With RngB
.MoveStartUntil Chr(11), wdForward
.End = .Start + 2
.Text = Chr(34) & ".) "
.Collapse wdCollapseEnd
.End = RngA.End
End With
.Collapse wdCollapseStart
.FormattedText = RngB.FormattedText
RngB.Text = vbNullString
End With
Application.ScreenUpdating = True
End Sub