XSLT grouping and transformation - xslt-1.0

Question

I have to transform XML file by grouping identical nodes and putting them into identical parent node.
The example file looks like this:
<cars>
<car>
<seller>A</seller>
<make>Ford</make>
<model>Mondeo</model>
<type>Hatchback</type>
</car>
<car>
<seller>A</seller>
<make>Ford</make>
<model>Mondeo</model>
<type>Sedan</type>
</car>
<car>
<seller>A</seller>
<make>Ford</make>
<model>Mondeo</model>
<type>Station wagon</type>
</car>
<car>
<seller>A</seller>
<make>Citroen</make>
<model>C5</model>
<type>Sedan</type>
</car>
<car>
<seller>A</seller>
<make>Citroen</make>
<model>C4</model>
<type>Hatchback</type>
</car>
<car>
<seller>A</seller>
<make>Citroen</make>
<model>C3</model>
<type>Hatchback</type>
</car>
<car>
<seller>A</seller>
<make>Opel</make>
<model>Corsa</model>
<type>Hatchback</type>
</car>
<car>
<seller>A</seller>
<make>Opel</make>
<model>Vectra</model>
<type>Sedan</type>
</car>
<car>
<seller>A</seller>
<make>Opel</make>
<model>Vectra</model>
<type>Station wagon</type>
</car>
</cars>
This file can include much more makes, models and types in a different order but there is always only one seller. I have to get it looking like that:
<cars>
<seller>A</seller>
<make name="Ford">
<model name="Mondeo" type="Hatchback"/>
<model name="Mondeo" type="Sedan"/>
<model name="Mondeo" type="Station wagon"/>
</make>
<make name="Citroen">
<model name="C5" type="Sedan"/>
<model name="C4" type="Hatchback"/>
<model name="C3" type="Hatchback"/>
</make>
<make name="Opel">
<model name="Corsa" type="Hatchback"/>
<model name="Vectra" type="Sedan"/>
<model name="Vectra" type="Station wagon"/>
</make>
</cars>
Before I tried that by checking if present model is the same as preceding-sibling but I couldn't to this to be "elastic" and could serve much more types of each model of each make.
I know how to transform one car node into desired format :
<?xml version="1.0" encoding="UTF-8"?>
<localEntry key="CarsXSL" xmlns="http://ws.apache.org/ns/synapse">
<xsl:stylesheet version="1.0" xmlns:xsi="http://www.w3.org/2001/XMLSchema-instance" xmlns:xsl="http://www.w3.org/1999/XSL/Transform" xmlns:xs="http://www.w3.org/2001/XMLSchema">
<xsl:output method="xml" omit-xml-declaration="yes"/>
<xsl:strip-space elements="*"/>
<xsl:template match="/">
<xsl:element name="cars">
<xsl:apply-templates/>
</xsl:element>
</xsl:template>
<xsl:template match="cars">
<xsl:element name="seller">
<xsl:value-of select="/cars/car[1]/seller/text()"/>
</xsl:element>
<xsl:element name="make">
<xsl:attribute name="name">
<xsl:value-of select="/cars/car/make/text()"/>
</xsl:attribute>
<xsl:element name="model">
<xsl:attribute name="name">
<xsl:value-of select="/cars/car/make/model/text()"/>
</xsl:attribute>
<xsl:attribute name="type">
<xsl:value-of select="/cars/car/make/model/type/text()"/>
</xsl:attribute>
</xsl:element>
</xsl:element>
</xsl:template>
</xsl:stylesheet>
</localEntry>
but I don't know how to group it by make and model and then how to put them into indentical parent node.
Is it even possible?

Answer 1

Try this: (updated as suggested by #michael-hor257k)
<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
xmlns:xs="http://www.w3.org/2001/XMLSchema"
exclude-result-prefixes="xs"
version="1.0">
<xsl:key name="card" match="car" use="make"/>
<xsl:key name="modeld" match="car" use="model"/>
<xsl:key name="types" match="car" use="concat(make, '_', model)"/>
<xsl:output indent="yes"/>
<xsl:template match="cars">
<xsl:copy>
<xsl:for-each select="car[generate-id() = generate-id(key('card', make)[1])]">
<xsl:copy>
<make name="{make}">
<xsl:for-each select="key('card', make)[generate-id() =
generate-id(key('modeld', model)[1])]">
<model name="{model}">
<xsl:copy-of select="key('types', concat(make, '_', model))/type"/>
</model>
</xsl:for-each>
</make>
</xsl:copy>
</xsl:for-each>
</xsl:copy>
</xsl:template>
</xsl:stylesheet>
See Transformation at https://xsltfiddle.liberty-development.net/6q1S8AD/1
For your Updated Question
<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
xmlns:xs="http://www.w3.org/2001/XMLSchema"
exclude-result-prefixes="xs"
version="1.0">
<xsl:key name="card" match="car" use="make"/>
<xsl:key name="types" match="car" use="concat(make, '_', model, '_', type)"/>
<xsl:output indent="yes"/>
<xsl:template match="cars">
<xsl:copy>
<seller>
<xsl:value-of select="//seller[1]"/>
</seller>
<car>
<xsl:for-each select="//car[generate-id() = generate-id(key('card', make)[1])]">
<make name="{make}">
<xsl:for-each select="key('card', make)[generate-id() = generate-id(key('types', concat(make, '_', model, '_', type))[1])]">
<model name="{model}" type="{type}"/>
</xsl:for-each>
</make>
</xsl:for-each>
</car>
</xsl:copy>
</xsl:template>
</xsl:stylesheet>
See Transformation at https://xsltfiddle.liberty-development.net/6q1S8AD/2